Les Heures du vent
An interactive fiction by Eole (2007) - the Inform 7 source text
Contents
Previous
Next
Complete text
[ - Les scenes - ]
Vent_frappeur is a scene. Vent_frappeur begins when play begins. Vent_frappeur ends when the volets1 are not opened for the first time.
Instead of waiting during Vent_frappeur:
say "Il essaya de se rendormir, mais finalement il se leva pour de bon, dérangé par le vent, et referma les volets.";
move player to ChambreAuberge;
now the volets1 are not opened.
Instead of waiting during Travail_de_nuit:
Try reading the Livre_conte1;
if the livre_conte1 is not held by the player, try silently taking the Livre_conte1;
now the nuit is over.
Partie1 is a scene. [Partie1 begins when Travail_de_nuit begins.]
Partie1 begins when play begins.
Partie1 ends when RencontreMagicien1 ends.
When Partie1 ends:
now PorteChambre is closed;
now PorteChambre is locked;
move MaireCorrompu to PlaceSudVillage;
move Fabrice to PlaceSudVillage;
now riviere is polluee.
Partie2 is a scene.
Partie2 begins when Partie1 ends.
Partie2 ends when the time since Partie2 began is 110 minutes.
When Partie2 ends:
if riviere is not bouchee and MoulinAube is not visited, now riviere is bouchee;
move nettoyeuse to AubergePrincipale;
move aubergiste to AubergePrincipale.
[say "bouchee ! (TODO)."]
[TODO : faire regions pour definir fin partie2 et voir 10.8. Multiple endings]
Travail_de_nuit is a scene. Travail_de_nuit begins when vent_frappeur ends.
[Travail_de_nuit ends when the player has livre_conte1 for the first time. ]
Travail_de_nuit ends when the nuit is over.
Nuit1 is a scene. Nuit1 begins when Vent_frappeur begins. Nuit1 ends when Travail_de_nuit ends.
Matinee1 is a scene. Matinee1 begins when Nuit1 ends. Matinee1 ends when Choix1 ends.
When Matinee1 ends:
move the nettoyeur to Void;
move aubergiste to AubergePrincipale;
move the nettoyeuse to PlaceFontaine33;
if the bidon is held by the nettoyeur, move bidon to AubergePrincipale;
if the petit marteau is held by the nettoyeur, move petit marteau to AubergePrincipale.
VisiteVillage1 is a scene. VisiteVillage1 begins when Nuit1 ends. VisiteVillage1 ends when the player is in the MaisonMagicien for the first time.
When VisiteVillage1 ends:
move nettoyeuse to MairieVillage.
RencontreMagicien1 is a scene. RencontreMagicien1 begins when VisiteVillage1 ends. RencontreMagicien1 ends when the player is informed.
[When RencontreMagicien1 ends:
move MaireCorrompu to PlaceSudVillage;
move Fabrice to PlaceSudVillage.]
[defini deja avec fin partie1]
Choix1 is a scene. Choix1 begins when RencontreMagicien1 ends. Choix1 ends when the player is in DehorsSauvage for the first turn.
Instead of waiting during VisiteVillage1:
say "Après avoir déambulé un peu dans les environs sans but précis, il se retrouva finalement devant la porte de l[']auberge. Il décida de prendre un nouveau chemin, pour aller directement chez son ami.";
Move Player to RuePavee13;
try going south;
try going south;
try examining Fontaine33;
try examining SculptureFontaine33;
try going west;
try going west;
try opening Manoir31.
Instead of waiting during RencontreMagicien1:
if player is not in MaisonMagicien or the player is not in BureauMagicien
begin;
move player to MaisonMagicien;
say "Il s[']était en effet quand même décidé à revenir sur ses pas, retourner près de son ami le magicien, puisque qu[']il était revenu dans ce village pour cette raison.";
end if;
try going north;
try talking to Magicien.
Instead of exiting when the location is BureauMagicien, try going south.
Instead of exiting when the location is MaisonMagicien, try going south.
Before going south when the location is MaisonMagicien during Partie1:
if a random chance of 80 in 100 succeeds
begin;
move the valet to location;
say "Au moment où il allait sortir, un des majordomes le rattrapa, et lui dit que son ami avait encore des choses à lui dire.";
stop the action;
otherwise;
move the servante to location;
say "Au moment où il allait sortir du manoir, une femme le rattrapa et lui dit que son ami avait encore des choses à lui dire.";
stop the action;
end if.
ReparationParquet is a scene. ReparationParquet starts when the nettoyeur is carrying 5 clous and petit marteau. ReparationParquet ends when Matinee1 ends.
Instead of waiting during Choix1:
say "Il ne savait plus trop quoi faire de lui-même, il fallait maintenant le mettre sur la piste.".
AuDehors1 is a scene. AuDehors1 begins when Choix1 ends. AuDehors1 ends when the player is [in OreeDuBois1 or] in GrandeVille for the first turn.
When AuDehors1 begins, move VieilleFemme1 to Riviere1.
VieilleFemmeCoule is a scene. VieilleFemmeCoule begins when VieilleFemme1 is in Riviere1.
VieilleFemmeCoule ends when VieilleFemme1 has baton or VieilleFemme1 is in Void.
VieilleFemmeCoule ends when AuDehors1 ends.
Every turn during VieilleFemmeCoule:
if player is in CheminForet1
begin;
say "Une vieille femme qui était tombée dans la rivière s[']époumonait en suppliant de sa voix rauque qu[']on la remonte sur la terre ferme.";
otherwise;
if player is in Village or in RuesVillage or in GrandeVille
begin;
[remove VieilleFemme1 from play;]
move VieilleFemme1 to Void;
now VieilleFemme1 is dead;
[say "La sorcière est morte.(TODO)";]
end if;
end if.
AuDedans1 is a scene. AuDedans1 begins when AuDehors1 ends.
[todo]
[Instead of waiting during AuDehors1, say " audehors1".
Instead of waiting during AuDedans1, say " audedans1".]
[- Fin des scenes -]