Petit Gnome
An interactive fiction by Otto Grimwald (2006) - the Inform 7 source text
Contents
Next
Complete text
Dehors is a region. SurLeToit, Jardin, Jardin2 and Maison are in Dehors.
East of Jardin is Jardin2. Above is SurLeToit.
Dedans is a region. Salon is in dedans.
Arrivee is a scene. Arrivee begins when the player is in SurLeToit for the first turn. Arrivee ends when the player is in Salon for the first turn.
[Thinking is being pensif.
Understand the command "penser [text]" as think.]
Instead of thinking during arrivee, say "Vous sentez que vous avez des problèmes avec cette maison."
Instead of thinking in SurLeToit, say "Depuis des siècles et des siècles, en plein coeur de l'hiver, vous devez aller de maison en maison pour délivrer des présents aux enfants."
SurLeToit is a room. The printed name of SurLeToit is "Sur le toit". "Après avoir effectué votre travail sur l'ensemble des bâtiments de cette petite ville provinciale, vous vous trouvez enfin sur le toit de la dernière des maisons à visiter."
Before looking in SurLeToit, display the Figure of titre.
After going in SurLeToit:
if SurLeToit is visited
begin;
say "Les montagnes au loin sont déjà auréolées des lueurs de l'aurore, vous êtes impatient de finir ce travail et de rentrer chez vous."; continue the action;
Otherwise;
say ""; continue the action;
end if;
The cheminée is in SurLeToit. Cheminée is a container. Cheminée is female. Understand "cheminee" as cheminée. The description of cheminée is "Les cheminées, ça vous les connaissez !"
The traineau is a vehicle in SurLeToit. Understand "traineau/rennes/chariot/cariole" as traineau.
Instead of going to salon when the player is in a vehicle, say "Vous ne pouvez entrer ici avec votre traineau.".
FinDuJeu is a scene. FinDuJeu begins when the player is in a vehicle. FinDuJeu ends when the player is in SurLeToit.
When FinDuJeu begins:
if cadeau is in cheminée or cadeau is on chenets
begin;
say "Vous avez enfin réussi à terminer votre tournée de cette année. Il est temps de rentrer chez vous.";
end the game in victory;
otherwise;
say "Vous ne pouvez vraiment pas partir ainsi en ne terminant pas correctement votre travail.";
end if.
When play begins:
move hotte to player;
move cadeau to hotte;
move carte to hotte.
The cadeau is a thing. Understand "paquet" or "cadeau" as cadeau.
The carte is a female thing. Understand "carte" or "cartes" as carte. The printed name of carte is "carte de visite". The description of carte is "Un paquet de cartes de visite à votre effigie que vous laissez généralement avec les cadeaux que vous livrez.".
Instead of showing carte to gnome, try giving carte to gnome.
Instead of giving carte to gnome for the first time:
say "Il prend la carte, et sursaute aussitôt.";
say "Après avoir fait une petite révérence, il se dirige alors vers la maison, et déverrouille la porte.";
move gnome to jardin;
change the PorteMaison to not locked.
Instead of giving cadeau to gnome, say "Il n'est veut pas. Il vous explique qu'il s'est déjà échappé d'un endroit où il devait en empaqueter des centaines par jour, aussi il n'aime plus ces choses. D'ailleurs en vous regardant il semble un peu vous craindre. ".
Instead of inserting cadeau into cheminée:
if chaussons is on chenets
begin;
continue the action;
award 2 points;
say "Vous entendez le bruit feutré du paquet qui tombe dans les chaussons. Et un heureux de plus !";
otherwise;
say "Vous ne pouvez pas, il vous semble qu'il y a un problème pour livrer ce cadeau.";
stop the action;
end if;
Jardin is a room. The printed name of Jardin is "Un beau jardin". "Ce petit jardin propret vous fait penser au vôtre. Sans doute qu'il y a là quelques gnomes agiles qui viennent l'entretenir. Il continue à s'étendre, sur votre droite, à l'est. La maison se trouve au sud."
Instead of examining Jardin for the second time, say "Vous êtes dans le jardin, tout près de la maison. Vous pouvez remonter sur le toit depuis ici."
Jardin2 is a room. The printed name of Jardin2 is "Le bout du jardin". "Vous êtes près de la limite de la propriété. Au delà s'étendent les autres jardins du voisinage."
After going in Jardin2:
if Jardin2 is not visited
begin;
display the Figure of gnome;
say ""; continue the action;
Otherwise;
say "" ; continue the action;
end if;
The gnome is in jardin2.
the gnome is a man. Understand "gnome/troll/créature/lutin" or "petit gnome" as Gnome. The description of Gnome is "C'est un lutin à l'air espiègle. Vous vous demandez si ce n'est pas lui qui garde la maison en l'absence de ses propriétaires".
chaussons are a thing. The printed name of chaussons is "deux chaussons".
GnomeCle is a thing. The printed name of GnomeCle is "clef". Understand "clé/clef/cle" as gnomecle.
[Instead of asking the Gnome about something, say "Vous parlez le langage gnome, mais celui-ci est resté si longtemps auprès des humains qu'il ne le connaît plus lui-même."]
Instead of attacking Gnome:
say "Il prend peur et se sauve en courant, laissant derrière lui une clé et une paire de chaussons.";
remove gnome from play;
move GnomeCle to location of the player;
move Chaussons to location of the player;
The PorteMaison is a door. It is south of Jardin and north of Salon. Salon is inside from Jardin. PorteMaison is female, locked and closed. The matching key of the PorteMaison is the GnomeCle. The printed name of PorteMaison is "porte d'entrée". The description of PorteMaison is "La porte de la maison est en acier qui semble épais."
Understand "portail/porte/seuil/entree" as PorteMaison.
[Instead of going to salon when the player is in Jardin:
if PorteMaison is closed,
say "Vous devez ouvrir la porte avant d'entrer.";
Otherwise continue the action.]
Instead of going to salon when the player is in Jardin:
if PorteMaison is not locked
begin;
try opening PorteMaison;
continue the action;
Otherwise;
say "La porte est verrouillée.";
end if.
Instead of pushing or pulling or attacking the PorteMaison for the first time:
say "Vous n'avez pas la force pour le faire, et quand bien même cela serait immoral.".
Every turn when in Jardin:
if PorteMaison is closed
begin;
if a random chance of 15 in 100 succeeds
begin;
say "Ne pensez-vous pas que vous devriez essayer d'entrer ?";
otherwise;
say "";
end if;
end if.
Instead of pushing or pulling or attacking the door for the second time, say "Voudriez-vous vous reconvertir dans le braquage ? Qu'en penserait votre femme ?"
Instead of pushing or pulling or attacking the door for the third time:
say "Vous voyez une voiture de police qui passe par là. Des policiers vous arrêtent et vous mettent directement en prison.";
end the game in death.