Les Heures du vent

An interactive fiction by Eole (2007) - the Inform 7 source text

Home page

Contents
Previous
Next

Complete text
Section 4 - Le livre de sorcellerie

The LivreSorcellerie is a thing. Understand "livre/manuel/ouvrage/sorcellerie/magie/kabbale/grimoire/reliure/encre/poudre/cuir" or "manuel de sorcellerie" or "ouvrage a la reliure noire" as LivreSorcellerie.
The printed name of LivreSorcellerie is "manuel de sorcellerie".
The description of LivreSorcellerie is "Ce livre ne lui inspirait rien qui vaille. Une reliure sale et malodorante, couverte de crasse, d[']encre et de poudre, des pages déchirées et cornées, tachées de traces de doigts, et un contenu sans doute diabolique. Les pages étaient en effet recouvertes de signes kabbalistiques incompréhensibles, ainsi que de formules écrites avec des lettres qu[']il reconnaissaient, mais qui ne signifiaient rien pour lui.".

Instead of reading LivreSorcellerie:
    say "Contre son gré, il lu quelques passages qui pour lui ne voulaient rien dire : [line break]";
    choose a random row in the table of Sorcelleries1;
    say "[apostrophe][sorcelleries1 entry]";
    choose a random row in the table of Sorcelleries1b;
    say "[sorcelleries1b entry] ";
    choose a random row in the table of Sorcelleries2;
    say "[sorcelleries2 entry] ";
    
    choose a random row in the table of Sorcelleries3;
    say "[sorcelleries3 entry]";
    choose a random row in the table of Sorcelleries3b;
    say "[sorcelleries3b entry][apostrophe] ! [line break]";
    say "Quel charabia...".

Instead of reading LivreSorcellerie when the player is metamorphosable:
    say "La première page du livre lui fut intelligible. Il y lu des histoires terrifiantes dont il aurait voulu aussitôt oublier l[']existence. Sans doute que son nouvel état de conscience devait lui permettre de connaître ces choses pour mieux pouvoir les rejeter ensuite. Il y apprit aussi comment il était possible, par de la sorcellerie analogique, d[']empoisonner des gens en mettant une copie d[']eux-même, ou un animal les symbolisant, dans un bocal avec des substances nocives. Le contenant devenait ainsi une prison pour le contenu. Une petite comptine figurait également là :[paragraph break] [contrerime des statues]".
    
Table of Sorcelleries1
sorcelleries1
"Dkak"
"Frottom"
"Bong"
"Afrenat"
"Bouamot"

Table of Sorcelleries1b
sorcelleries1b
"la"
"a"
"i"
"o"
"u"
"lu"

Table of Sorcelleries2
sorcelleries2
"ikka"
"gligli"
"driri"

Table of Sorcelleries3
sorcelleries3
"mir"
"grir"
"kil"
""
""

Table of Sorcelleries3b
sorcelleries3b
"u"
"a"
"o"
""
""