Les Heures du vent
An interactive fiction by Eole (2007) - the Inform 7 source text
Contents
Previous
Next
Complete text
[Description du village]
The PorteChambre is a scenery door. It is east of ChambreAuberge and west of CouloirAuberge. PorteChambre is female and closed. The printed name of PorteChambre is "porte de la chambre". The description of PorteChambre is "La porte de la chambre menait vers le reste de l[']auberge.". Understand "porte/seuil/chambre" or "porte de la chambre" as PorteChambre. The indefinite article of PorteChambre is "la".
[ChambreAuberge is west from CouloirAuberge.]
The printed name of AubergePrincipale is "Auberge". The description of AubergePrincipale is "La salle principale de l[']auberge, banale et pourtant dépaysante. [if Matinee1 is happening]On ne pouvait pas dire que ce lieu était très animée durant la matinée. [otherwise]Il y avait quelques habitués ici, ainsi que l[']aubergiste. [end if]".
[[if Matinee1 is happening]Il n[']y avait qu['][end if][if nettoyeuse in location]une femme qui nettoyait l[']endroit, ainsi qu['][end if][if nettoyeur in location]un homme occupé à huiler les sols[end if].]
The nettoyeur is a male man in AubergePrincipale. Understand "homme/servant/ouvrier" as nettoyeur. The printed name of nettoyeur is "un ouvrier". The description of nettoyeur is "Il y avait un homme occupé [if ReparationParquet is happening]à clouer quelques lames de parquet défaites[otherwise]à huiler les sols[end if].". [todo : pb affichage : "un" ouvrier ]
Instead of talking to nettoyeur when nettoyeuse is in location, say "Il regarda brièvement autour de lui, et déclara ensuite qu[']il avait du travail en ce moment mais pas de temps pour discuter.".
Instead of talking to nettoyeur when the petit marteau is not held by nettoyeur and nettoyeuse is not in location, say "Il lui raconta qu[']il était bien embêté, car il venait de remarquer qu[']il avait oublié [if 5 clous are held by nettoyeur]son marteau[otherwise]son marteau et ses clous[end if] pour réparer quelques lames de parquets.".
Instead of giving petit marteau to nettoyeur:
if 5 clous are held by nettoyeur
begin;
say "Il sursauta de surprise. Sa surprise passée, il hocha du chef d[']un air reconnaissant, et laissa de côté son bidon pour se concentrer sur la réparation des lames de parquet.";
now the bidon is in location;
now the nettoyeur is carrying petit marteau;
otherwise;
say "Il voulait bien de ce marteau, mais il lui fallait des clous avant tout.";
end if.
Before giving clou to nettoyeur:
[if the player is carrying more than 5 clous]
if 5 clous are held by nettoyeur
begin;
say "L[']ouvrier précisa qu[']il avait dorénavant suffisamment de clous pour effectuer sa réparation en toute tranquillité.";
stop the action;
otherwise;
if the sac is containing more than 4 clous
begin;
say "Très bien, l[']ouvrier avait maintenant quelques clous, il ne lui manquait plus qu[']un marteau pour pouvoir commencer à travailler.";
bring 5 clous to the nettoyeur; [todo : switch pour desactive clous]
stop the action;
otherwise;
if player is carrying sac
begin;
say "Il ouvrir son sac pour montrer ce qu[']il avait en matière de clous, mais l[']ouvrier lui fit comprendre poliment qu[']il avait besoin d[']un peu plus de clous que cela.";
stop the action;
otherwise;
say "L[']ouvrier fit comprendre poliment qu[']il avait besoin d[']un peu plus de clous que cela.";
stop the action;
end if;
end if;
end if.
[todo : ajouter addition avec clous dans sac]
Instead of talking to the nettoyeur when the petit marteau is held by the nettoyeur, say "Il le remercia encore pour son aide.".
The nettoyeuse is a female woman in AubergePrincipale. Understand "femme/soubrette/servante/serveuse" as nettoyeuse. The printed name of nettoyeuse is "serveuse". The description of nettoyeuse is "[if the location is in AubergePrincipale or the location is in MairieVillage]Il y avait une femme qui nettoyait l[']endroit[otherwise]La femme n[']avait rien de spécial, elle était très commune, et plus très jeune[end if][if the location is PlaceFontaine33]. Elle était assise sur la margelle de la fontaine.[line break][end if]".
Nettoyeuse hello, Nettoyeuse weather, Nettoyeuse quete, Nettoyeuse queteSolved, Nettoyeuse moulin are chat nodes.
Instead of talking to Nettoyeuse: run a conversation from Nettoyeuse hello.
Instead of giving text for Nettoyeuse hello: say "[if location is in Village]Elle avait du travail et n[']avait pas beaucoup de temps[otherwise]Elle lui dit qu[']elle était assez pressé en ce moment[end if]. Néanmoins, il était quand même possible de s[']entretenir avec elle de ces quelques sujets :" ; now the Nettoyeuse is recognised. Instead of finding responses to Nettoyeuse hello: link to Nettoyeuse weather; if fou is in Montagne1, link to Nettoyeuse quete; if fou is betrayed and fou is dead, link to Nettoyeuse queteSolved; if moulin is visited, link to Nettoyeuse moulin.
Instead of giving link to Nettoyeuse weather: say "Parler du temps". Instead of giving text for Nettoyeuse weather: say "Elle lui raconta alors avec beaucoup de détail comment le temps pouvait varier du tout au tout suivant les saisons, chaud et lourd en été, sans un brin de vent, tandis qu[']il faisait froid avec un vent à décorner les balhurons à partir de la saison automnale.".
Instead of giving link to Nettoyeuse quete: say "Lui demander comment elle allait". Instead of giving text for Nettoyeuse quete: say "Elle avoua qu[']une espèce de fou terrorisait les ménagères qui passait dans la montagne pour aller cueillir des baies, il les empêchait de passer par le chemin habituel, les obligeant à faire un long détour pour arriver là où elles voulaient aller. Elle en avait parlé aux soldats et au maire, mais ils ne semblaient pas disposés à faire quelque chose pour le moment, malgré leurs vagues promesses. Elle lui serait très reconnaissante s[']il pouvait les débarrasser de cet homme dangeureux."; now the fou is betrayed.
Instead of giving link to Nettoyeuse queteSolved: say "Lui annoncer qu[']il s[']était occupé du fou". Instead of giving text for Nettoyeuse queteSolved: say "Elle le remercia pour ses efforts, et en échange lui donna comme conseil d[']éviter le maire qui était mauvais comme du poisson pourri et se livrait à des pratiques douteuses lorsque ses villageois étaient couchés. Avant de partir, elle se souvint qu[']elle pouvait également lui donner un petit quelque chose, il s[']agissait d[']un petit cierge qui, affirmait-elle, pourrait le protéger. Elle le sortit de sous son tablier et le déposa près de lui." ; move bougie2 to player ; deactivate Nettoyeuse queteSolved.
Instead of giving link to Nettoyeuse moulin: say "Parler du moulin". Instead of giving text for Nettoyeuse moulin: say "Elle avoua qu[']elle était bien contente que le maire ne lui demande pas d[']aller nettoyer ce moulin, car il y avait de la surface et la poussière y abondait !" ; deactivate Nettoyeuse moulin.
The balais is held by nettoyeuse.
The bougie2 is a female device. The description of bougie2 is "Une simple chandelle. Celle-ci a quand même le luxe d[']être en cire au lieu d[']être constituée de suif.". The printed name of bougie2 is "bougie blanche". Understand "chandelle/bougie/cierge/cire/blanche" or "bougie blanche" as bougie2.
[After printing the name of bougie2: omit contents in listing.]
Before switching on bougie2:
say "[if bougie2 is not lit]Il alluma la bougie, qui émit une douce lueur blanche.[otherwise]La bougie était déjà allumée.[end if]";
now the bougie2 is lit;
now the bougie2 is switched on;
stop the action.
Before switching off bougie2:
if bougie2 is lit
begin;
now the bougie2 is not lit;
say "Il éteignit la lampe.";
now the bougie2 is switched off;
stop the action;
otherwise;
say "La lampe était déjà éteinte.";
stop the action;
end if.
The bidon is a ContainerHuile. It is held by the nettoyeur. [in AubergePrincipale.] Instead of pushing or pulling the bidon when the nettoyeur is in location, say "L[']homme se servait de cela, et ne voulait pas s[']en séparer.".
Understand "bidon/huile" or "bidon huile" as bidon. The printed name of bidon is "bidon d[']huile".
The bidon is full.
The description of bidon is "[if bidon is full]Le bidon était plein d[']huile[otherwise]Le bidon était vide[end if]."
Instead of emptying bidon:
if bidon is full
begin;
say "Il vida le bidon, son contenu se répandit sur le sol.";
now the bidon is empty;
otherwise;
say "Ce bidon était déjà vide.";
end if.
The bidonEau is a ContainerEau. Understand "bidon/eau" or "bidon eau" or "bidon d'eau" as BidonEau. The printed name of BidonEau is "bidon d[']eau".
The description of bidonEau is "[if bidonEau is full]Le bidon était plein d[']eau[otherwise]Le bidon était vide[end if]."
The bidonEau is full.
Instead of emptying bidonEau:
if bidonEau is full
begin;
say "Il vida le bidon, son contenu se répandit sur le sol.";
now the bidonEau is empty;
otherwise;
say "Ce bidon était déjà vide.";
end if.
Instead of filling bidon when the location is PlaceFontaine33:
if riviere is not bouchee
begin;
if bidon is not full
begin;
remove bidon from play;
move bidonEau to player;
now the bidonEau is full;
say "Il remplit le bidon à la fontaine.";
otherwise;
say "Le bidon était encore plein d[']huile.";
end if;
otherwise;
say "Il n[']y avait plus d[']eau dans cette fontaine.";
end if.
Instead of filling bidonEau when the location is PlaceFontaine33:
if riviere is not bouchee
begin;
if bidonEau is not full
begin;
say "Il remplit le bidon à la fontaine.";
now the bidonEau is full;
otherwise;
say "Le bidon était encore plein d[']eau.";
end if;
otherwise;
say "Il n[']y avait plus d[']eau dans cette fontaine.";
end if.
Instead of filling bidon with fontaine33, try filling bidon.
Instead of inserting fontaine33 into bidon, try filling bidon.
Instead of filling bidonEau with fontaine33, try filling bidonEau.
Instead of filling bidonEau with bidonEau, try filling bidonEau.
Instead of filling bidon with when the location is CheminForet1, say "Il n[']était pas possible d[']atteindre les bords de la berge qui étaient trop glissants.".
Instead of drinking riviere1, say "La rivière n[']était pas accessible.".
Instead of filling bidon with riviere1, try filling bidon.
The aubergiste is a man in Void. Understand "homme" as aubergiste. Instead of talking to aubergiste, say "Étonnamment, cet aubergiste ne fut pas très locace à ce moment.".
[todo : mettre un petit dialogue avec homme?]
Some sols are scenery in AubergePrincipale.
The rideau2 is door in CouloirAuberge. It is east of CouloirAuberge and west of AubergePrincipale. The printed name of rideau2 is "rideau". The description of rideau2 is "Un long rideau en lin, qui pouvait occulter si nécessaire l[']entrée de la salle principale de l[']auberge.". Understand "rideaux/rideau" as rideau2. The rideau2 is male.
instead of pulling rideau2, try opening rideau2.
CouloirAuberge is outside from ChambreAuberge.
The description of CouloirAuberge is "Un petit couloir sinistre qui menait de la chambre à l[']ouest au reste de l[']auberge à l[']est. Une porte permettait de sortir vers le sud.".
The FouleVillage is a female backdrop.
FouleVillage is in RuesVillage and in PlaceFontaine33 and Place31 and Ville.
The printed name of FouleVillage is "foule".
Understand "personnes/foule/homme/femme/enfants/hommes/femmes/gens" as FouleVillage.
The description of FouleVillage is "Il y avait ici quelques personnes.".
Instead of touching or pushing or pulling FouleVillage, say "La foule était partout.".
Procedural rule when kissing FouleVillage:
[ignore the check life property for kissing rule ;]
ignore the block kissing rule.
[Procedural rule when talking to FouleVillage:
ignore the block telling rule.]
Before kissing FouleVillage:
say "La foule était partout, cela n[']était pas possible de faire cela.";
stop the action.
Before talking to FouleVillage:
say "Il était habitué à leur conter ses histoires, mais lorsque le moment était opportun, et il n[']avait rien à leur dire de cette façon dans la rue.";
stop the action.
The PorteAuberge is a door. It is south of CouloirAuberge and north of RuePavee13. PorteAuberge is closed. The printed name of PorteAuberge is "porte d[']entrée". The description of PorteAuberge is "La porte de l[']auberge.". Understand "porte/seuil/entree/dehors" as PorteAuberge.
After deciding the scope of the player while in RuesPaveesVillage: place the PlaceFontaine33 in scope.
Instead of examining PanneauFontaine33 when in RuesPaveesVillage, say "Cela se trouvait encore trop loin pour en voir tous les détails.".
Instead of examining SculptureFontaine33 when in RuesPaveesVillage, try examining PanneauFontaine33.
The printed name of CouloirAuberge is "Couloir de l[']auberge".
Instead of going east from CouloirAuberge during Nuit1, say "Il ne pouvait pas entrer dans la salle principale de l[']auberge durant la nuit, cela ne se faisait pas et aurait pu être mal interprété s[']il avait été découvert."
After going south from CouloirAuberge during Nuit1:
say "Il faisait encore très froid et lugubre dehors, aussi il préféra rentrer dans l[']abri relatif qu[']offrait l[']auberge.";
try going north.