Les Heures du vent
An interactive fiction by Eole (2007) - the Inform 7 source text
Contents
Previous
Next
Complete text
Some barraquements are backdrops in GrandeVille.
Some soldats are a man. Understand "[soldats]" as the soldats. The description of the soldats is "Les soldats étaient partout en ville." Understand "soldats/soldat/gardes/officier/garde/molosse/armure/hallebarde/cotte/de/mailles" as "[soldats]".
Soldats are in GrandeVille.
Some TroupesEnnemies are a thing. Understand "troupes/ennemis" or "troupes ennemies" as TroupesEnnemies. The printed name of TroupesEnnemies is "troupes ennemies".
The description of TroupesEnnemies is "Les troupes étaient encore trop loin pour pouvoir bien les détailler. Elles étaient nombreuses, et semblaient bien armées.". [TODO]
Instead of attacking TroupesEnnemies, say "Il n[']aurait servi à rien de faire une manoeuvre aussi désespérée qu[']inutile. À ce moment, les deux armées étaient en train de se jauger, et il fallait attendre les ordres avant d[']agir.".
After deciding the scope of the player while in Ville: place the GrandeVille in scope.
Instead of talking to soldats for the first time, say "Un soldat lui expliqua rapidement que l[']armée régulière venait renforcer la ville pour protéger le prince, car le royaume voisin avait déclaré la guerre et s[']apprêtait à venir envahir la région.".
Instead of talking to soldats for the second time, say "Il rencontra un officier qui lui fit comprendre que s[']il voulait rester dans la ville, il lui faudrait oublier son activité de saltimbanque, car la guerre était imminente. Il lui désigna un endroit où il pourrait être armé et préparé à ces événements, près de la place du marché vers l[']ouest.".
Instead of talking to soldats for the third time, say "Il apprit que les terres de l[']ouest avaient levé leurs troupes en direction de la région, et cette ville était le premier poste qu[']elles rencontreraient. Les habitants auraient dû s[']attendre et se préparer à une telle éventualité, mais maintenant il était un peu tard et il fallait parer au plus pressé.".
Before talking to soldats when the location is not GrandeVille, say "Cet endroit n[']était pas le meilleur endroit pour discuter avec des soldats.".
Instead of talking to soldats:
if a random chance of 50 in 100 succeeds
begin;
say "Les soldats le repoussèrent brutalement tandis qu[']il se tenait sur leur chemin, et ils continuèrent à vaquer à leurs occupations.";
otherwise;
say "Les hommes de guerre n[']eurent pas le temps de discuter avec lui et continuèrent sans lui prêter attention.";
end if.
After going to GrandeVille for the first time:
choose a blank row in the table of conte2_heros;
change heros entry to "d[']un soldat";
choose a blank row in the table of conte2_problemes;
change problemes entry to "devait entrer en guerre";
say "[imagination of player] d[']un soldat partant en guerre.";
continue the action.
Before talking to soldats for the fourth time:
choose a blank row in the table of conte2_problemes;
change problemes entry to "avait l[']impression désagréable de se sentir inutile";
say "[imagination of player] de quelqu[']un qui se sentait inutile.";
continue the action.
Instead of going north when in GrandeVille:
say "Il erra quelques temps dans les ruelles vides de la ville, jusqu[']à atteindre une place un peu plus animée. ";
try going west.
Instead of going northwest when in GrandeVille:
say "Il erra quelques temps dans les ruelles vides de la ville, jusqu[']à atteindre une place un peu plus animée. ";
try going west.
The description of PlaceGrandeVille is "[if not visited][end if]Un marché semblait s[']être déroulé ici peu de temps auparavant, car des détritus divers remplissaient le sol pavé de la place, et une grande agitation troublait la quiétude qu[']il y avait habituellement par ici. Les portes de la ville devaient se trouver vers l[']est à partir d[']ici. Au sud, un bâtiment vaste et lumineux semblait être le centre de tous les mouvements de la place.".
The printed name of PlaceGrandeVille is "Place principale".
The BureauRecrutementFake is scenery in PlaceGrandeVille. The printed name of BureauRecrutementFake is "bâtiment". Understand "batiment/centre" or "batiment vaste et lumineux" as BureauRecrutementFake.
Instead of entering BureauRecrutementFake, try going south.
Instead of going north when in PlaceGrandeVille, say "En ces périodes troubles, les quartiers les plus pauvres étaient autant de traquenards à éviter.".
Instead of going west from PlaceGrandeVille, try going north.
The printed name of BureauRecrutement is "Bureau de recrutement". The description of BureauRecrutement is "Il arriva dans une grande salle qui faisait également office de cantine. Des armes et des équipements de soldats étaient disposés sur les tables, prêt à être distribués aux nouvels arrivants.
Le ribaud qui officiait en tant que recruteur attendait que l[']on vienne s[']inscrire auprès de lui."
The ribaud is a man in BureauRecrutement. Understand "homme/officier/soldat" as ribaud. The printed name of ribaud is "officier".
The description of ribaud is "Un homme sec et à l[']air retord. Il portait une tenue de soldat complète, et vu sous cet angle, l[']uniforme avait un certain prestige.".
The nourriture is female scenery in BureauRecrutement. Instead of taking nourriture, say "La nourriture était réservée aux recrutés.".
The épée is a weapon in void. Understand "epee" as épée.
The équipement is scenery in BureauRecrutement. Instead of taking équipement, say "L[']équipement était réservé aux recrutés.". Understand "armes/equipements" as équipement.
Ribaud hello, Ribaud divers, Ribaud weather, Ribaud Ribaud, Ribaud Engage, Ribaud politics, Ribaud livre and Ribaud Recrutement are chat nodes.
Instead of talking to Ribaud: run a conversation from Ribaud hello.
Instead of giving text for Ribaud hello: say "[if Ribaud is unknown]Cet homme lui dit qu[']il était l[']officier recruteur de la ville. [otherwise][end if]Zéphyr pouvait aborder avec lui ces divers sujets :" ; now Ribaud is recognised. Instead of finding responses to Ribaud hello: link to Ribaud divers; link to Ribaud Ribaud; link to Ribaud weather; link to Ribaud Recrutement; link to Ribaud Engage; link to Ribaud politics; if the player is informed, link to Ribaud livre.
Instead of giving link to Ribaud divers: say "Parler de tout et de rien". Instead of giving text for Ribaud divers: say "Il lui avoua ne pas connaître grand chose de cette région." ; deactivate Ribaud divers.
Instead of giving link to Ribaud Ribaud: say "Le questionner sur lui-même". Instead of giving text for Ribaud Ribaud: say "Il raconta comment dans sa jeunesse il fut un jeune homme désoeuvré et violent, et que plus tard l[']armée lui avait donné une famille et une raison de vivre, le sortant de son désoeuvrement.".
Instead of giving link to Ribaud weather: say "Parler du temps". Instead of giving text for Ribaud weather: say "Il lui répondit que le temps n[']était rien, face à ce qui allait déferler sur la région d[']ici peu." ; deactivate Ribaud weather.
Instead of giving link to Ribaud Recrutement: say "Parler du recrutement". Instead of giving text for Ribaud Recrutement: say "Il lui expliqua que l[']engagement était définitif, mais qu[']il assurait un repas pour tous.". [todo]
Instead of giving link to Ribaud politics: say "Parler de politique". Instead of giving text for Ribaud politics: say "Le ribaud était certain que cette guerre était juste et que ceux qui s[']engagaient allaient oeuvrer pour la paix des générations futures."; deactivate Ribaud politics.
Instead of giving link to Ribaud livre: say "Parler de la bibliothèque de la ville". Instead of giving text for Ribaud livre: say "Le ribaud lui répondit que le quartier de la bibliothèque avait été complètement bouclé car il allait se retrouver en première ligne des pillards. Seuls les gardes d[']élite pourraient y accéder lors des affrontements qui allaient être imminents. À la question de Zéphyr concernant le livre de contes qui aurait pu se trouver dans cette bibliothèque, le ribaud rétorqua que ces livres n[']avaient plus beaucoup d[']importance s[']il n[']y avait plus de parents pour les lire à leurs enfants."; deactivate Ribaud livre.
Instead of giving link to Ribaud Engage: say "Demander à s[']engager dans l[']armée".
Instead of giving text for Ribaud Engage:
if Marguerite is visible
begin;
say "La jeune femme s[']interposa, et lui conseilla de réfléchir à deux fois avant de faire cela. Elle ne voulait pas qu[']ils se quittent ainsi, et elle avait vu trop de morts dans sa vie pour le laisser prendre cette décision à la légère."; Now Marguerite is BavardeMorts;
end if;
say "Voulait-il vraiment signer son engagement ?";
if player consents
begin;
say "L[']homme sourit d[']un air mauvais, il lui prit toutes ses affaires, et lui proposa le paquetage de base du soldat à la place." ; now every thing carried by the player is carried by Ribaud; now épée is carried by the player; deactivate Ribaud Engage;
now the histoire is à la fin;
now the player is soldat;
now Marguerite is not seduced;
otherwise;
say "Il se ravisa et ne signa rien du tout.";
end if.
Before going east when in GrandeVille:
if the player is soldat
begin;
say "Des gardes le reconnurent, et lui dirent que les soldats n[']avaient pas le droit de quitter la ville, aussi il ferait mieux de rejoindre son unité.";
stop the action;
otherwise;
continue the action;
end if.
[
Il lui prit toutes ses affaires, et lui proposa le paquetage de base du soldat à la place.
]
Affrontements is a scene.
Affrontements begins when the histoire is à la fin.
Affrontements ends when the histoire is finie.
When affrontements begins:
remove vent from play;
if the maireCorrompu is living
begin;
move portail to MoulinHaut;
move maireCorrompu to MoulinHaut;
end if;
if the bailli is living, move bailli to MoulinHaut;
move Magicien to Place31.
[say "Les hordes armées de l[']ouest déferlèrent TODO.".]
When affrontements ends:
remove TroupesEnnemies from play;
remove AuraMoulin from play;
remove soldats from play.
[say "Les hordes armées de l[']ouest déferlèrent TODO.".]
Every turn during affrontements:
if the time since affrontements began is 3 minutes
begin;
now the selle is rideable;
remove caleche from play;
remove relaisFake from play;
move briques to RelaisVille;
move AuraMoulin to CheminVille1;
now Moulin is haunted;
move TroupesEnnemies to RelaisVille;
say "[if the location is in Ville]Le vent cessa alors brusquement de souffler, et une très forte déflagration se fit sentir au loin, pourtant aucun son ne fut entendu. La présence du silence fut pendant un bref instant terriblement angoissante, mais tout redevint comme avant au bout de quelques secondes, excepté pour le vent qui disparut bel et bien[end if][if the location is in Village]Le vent cessa alors brusquement de souffler, et une très forte déflagration se fit sentir au loin, pourtant aucun son ne fut entendu. La présence du silence fut pendant un bref instant terriblement angoissante, mais tout redevint comme avant au bout de quelques secondes, excepté pour le vent qui disparut bel et bien[end if][if the location is in dehors]Le vent cessa alors brusquement de souffler, et une très forte déflagration se fit sentir au loin, pourtant aucun son ne fut entendu. La présence du silence fut pendant un bref instant terriblement angoissante, mais tout redevint comme avant au bout de quelques secondes, excepté pour le vent qui disparut bel et bien[end if].";
end if;
if the time since affrontements began is 5 minutes
begin;
say "[if player is soldat]Les clameurs des autres soldats redevinrent très présentes, et le rassemblement fut sonné, pour un regroupement immédiat sur la place principale.[line break][end if]";
end if;
if the time since affrontements began is 8 minutes
begin;
if the player is soldat
begin;
if the location is PlaceGrandeVille
begin;
say "Le général de la garnison vint faire un bref discours sur la valeur du soldat, et annonça ensuite que l[']ennemi n[']était pas passé comme ils s[']y attendaient par les montagnes puis par le grand désert de l[']ouest, mais qu[']il venait d[']arriver par un moyen magique au coeur même de la région, sans doute aidé en cela par la traîtrise d[']un agent sur place. Il encouragea alors ses troupes pour le combat, et des chants furent entonnés, pendant que les soldats se dirigeaient en ordre vers la sortie de la ville garnison. Zéphyr suivit le mouvement, et il s[']ensuivit une longue marche vers l[']est, en direction des ennemis.";
move player to RelaisVille;
otherwise;
say "Alors que tout le monde était déjà rassemblé, Zéphyr errait encore sans but, et des soldats l[']arrêtèrent et l[']emprisonnèrent pour désertion.";
end the game saying "Au moins il n[']aurait pas à participer à une guerre sans doute perdue d[']avance.";
end if;
end if;
end if.