Sarvegne

An interactive fiction by Eric Forgeot (2006) - the Inform 7 source text

Home page

Contents

Complete text
"Sarvegne" by Eric Forgeot

[ -- Description du jeu ]

The story headline is "Une visite qui conduit loin."
The story genre is "Aventure".
The story creation year is 2006.
The release number is 2.
The story description is "Aventure dans un monde parallèle : Ce jour-là, vous étiez décidé à aller lui rendre visite, dans la mythique cité de Sarvegne protégée du monde extérieur et de ceux qui fouillent un peu trop dans ses affaires politiques... <br><br><small>Aventure réalisée initialement à l'occasion du concours de fiction interactive francophone, avec le système Inform 7. Préférez le fichier en version glulx, qui présente des images et des musiques. Le fichier zblorb est la même chose avec une extension différente.</small>".

Release along with the source text, cover art, a website, a file of "Version glulx" called "sarvegne.blb" , a file of "Version z5" called "sarvegne.z5", a file of "Solution" called "sarvegne-solution-rec.txt", a file of "Plan" called "sarvegne-plan.pdf" [solution, the introductory booklet].

[ -- Ajustements techniques ]

Use MAX_PROP_TABLE_SIZE of 60000.
Use MAX_ZCODE_SIZE of 60000.
Use MAX_VERBSPACE of 8000.

Use MAX_ARRAYS of 1500.
Use MAX_CLASSES of 200.
Use MAX_VERBS of 300.
Use MAX_STATIC_DATA of 30000.
Use MAX_INDIV_PROP_TABLE_SIZE of 20000.
Use MAX_VERBSPACE of 8000.

Procedural rule: ignore the print final score rule.
Use full-length room descriptions.

Figure of lettrage is the file "lettres.png".
Figure of sarvegne is the file "sarvegne.jpg".
Figure of sarvegne2 is the file "sarvegne2.jpg".
Figure of titre is the file "sarvegne-titre.jpg".
Figure of plansarvegne is the file "sarvegne-plan.png".


Include French by Eric Forgeot.

[ -- divers ]

Instead of waiting:
    choose a random row in the Table of Attente;
    say "[response entry][paragraph break]";
    continue the action.

Table of Attente
response
"Vous baillez."
"Vous attendez un peu en méditant sur vos actions passées."
"Vous passez d'un pied sur l'autre pour occuper votre temps."


[Check quitting the game:
say "Etes vous certain de vouloir quitter cette aventure ?";
if player consents
    begin;
        end the game saying "[line break]A bientôt.[line break]";
otherwise;
        stop the action;
end if.]

[When play begins:
change left hand status line to "Proche : [if a room is adjacent][the list of adjacent rooms][end if][if a room is adjacent and a door is visible] et [end if][if a door is visible][the list of visible doors][end if]";
change right hand status line to "".


Rule for printing the name of an unvisited room (called the target) while constructing the status line:
let aim be the best route from the location to the target;
say "un endroit au [aim]".


After printing the name of a visited room (called the target) while constructing the status line:
let aim be the best route from the location to the target;
say " ([aim])".



Rule for printing the name of a direction (called the aim) while constructing the status line:
choose row with a heading of the aim in the Table of Abbreviation;
say "[shortcut entry]".

Table of Abbreviation
heading    shortcut
north    "N"
northeast    "NE"
northwest    "NW"
east    "E"
southeast    "SE"
south    "S"
southwest    "SW"
west    "W"
up    "U"
down    "D"
inside    "dedans"
outside    "dehors" ]



[Understand "recommencer" as restarting the game.]


Understand "effrayer [someone]" as attacking.

Understand "chercher [something]" as searching.


[Understand "tell [someone] about [something]" as asking someone about something.]

    
[ -- smart can't go ]

Instead of going nowhere:
let place be location;
let count of exits be 0;
repeat with way running through directions
begin;
let place be the room way from the location;
if place is a room, increase count of exits by 1;
end repeat;
if the count of exits is 0, say "Vous semblez être piégé ici." instead;
if the count of exits is 1, say "La seule sortie est";
otherwise say "Les directions possibles sont";
say exit list with a total of count of exits.

To say exit list with a total of (sum - a number):
let place be location;
let index be sum;
repeat with way running through directions
begin;
let place be the room way from the location;
if place is a room
begin;
say " [way]";
decrease index by 1;
if index is 1
begin;
if sum is 2, say " et";
otherwise say ", et";
otherwise;
if index is 0, say ".";
otherwise say ",";
end if;
end if;
end repeat.

[ -- way back]

The former location is a room that varies.

First carry out going rule:
change the former location to the location.


Understand "revenir" as retreating. Understand "retour" or "return" or "retreat" as retreating.

Retreating is an action applying to nothing.

Carry out retreating:
let way be the best route from the location to the former location, using doors;
if way is a direction, try going way;
otherwise say "Vous ne pouvez voir de voie libre."


Understand "ask [someone] about [something]" as asking it about specified object. Understand "tell [someone] about [something]" as asking it about specified object. Asking it about specified object is an action applying to two visible things. Carry out asking it about specified object: say "[The noun] just shrugs." [Asking something about specified object something is useless action. ]







The sacdos is a player's holdall. The printed name of sacdos is "sac à dos". Understand "sac" or "sac à dos" or "sac a dos" as sacdos. The player is wearing the sacdos.

The carrying capacity of the player is always 4.

[ -- Atmospheric Effects start -- ]
Include Atmospheric Effects by Mikael Segercrantz.

Table of Dehors effects
   atmospheric message   used
   "Des navettes passent rapidement dans le ciel."   2
   "Des nuages gris s'amoncellent au dessus de la région." 1
   "Le vent souffle légèrement." 2
   "Un avion fait un peu de bruit en traversant le ciel avant de disparaître au loin." 1
   "Un oiseau de proie essaye d'attraper un serpent, mais ce dernier est plus rapide et parvient à s'échapper." 1
   "Le soleil commence à revenir." 1
  
The atmospheric table of Dehors is the Table of Dehors effects.
The initial chance of Dehors is 25.

[ --Atmospheric Effects stop -- ]