Le Scarabée et le Katana

An interactive fiction by Eric Forgeot (2007) - the Inform 7 source text

Home page

Contents
Previous
Next

Complete text
Part 2 - Le jeu

Chapter 1 - Les lieux, le décor et l'histoire

Dedans is a region.
Dehors is a region.

Cage is a recurring scene. Cage begins when scarabee is inside cachette for the second turn. Cage ends when scarabee is in Temple.

Protege is a scene. Protege begins when play begins.
Protege ends when the player is in Dehors for the first turn and nuit is happening.

Traque is a scene. Traque begins when Protege ends.

Nuit is a scene. Nuit begins when play begins. Nuit ends when the player is asleep for the first turn.

Jour is a scene. Jour begins when Nuit ends.

[Every turn during Nuit:
    if the player is in Dehors
    begin;
        say "Il fait nuit.";
    otherwise;
        say "";
    end if.]

Combat is a scene. Combat begins when the player is in Foret for the second turn.

When combat begins:
    say "L'affrontement commence... ";
    try attacking ninjas.

A person is either awake or asleep. A person is usually awake.

Instead of sleeping when the player is in Dehors:
    say "Cet endroit n'est pas le plus adapté ni le plus sûr pour faire un petit somme...".

Instead of sleeping when the armure is worn:
    say "Dormez-vous avec une armure de plate ? Le traditionalisme a ses limites tout de même...".
    
Instead of sleeping during nuit: now the player is asleep; say "Vous vous endormez.";
    if Traque is happening and (the katana is magic or fantomes are in parvis)
        begin;
        say "Vous vous réveillez quelques heures plus tard, avec l'impression d'avoir été protégé durant votre sommeil par des forces extérieures aux vôtres.";
        otherwise;
        if Traque is happening
        begin;
        say "Durant votre sommeil, vous ne faites pas attention aux tueurs de l'ombre qui entrent discrètement dans le temple pour vous y enlever."; end the game in death;
        play the sound of Perdu;
        otherwise;
        say "Vous vous réveillez quelques heures plus tard, en pleine forme.";
        display the figure of Jour;
        end if;
    end if.


Table of Stress
evenement
"des pas sur le parvis du temple"
"un craquement dans le toit du temple"
"un cri étouffé au loin"
"un bruissement dans le feuillage des palmiers aux alentours"
"un bruit sourd"


When protege ends:
    display the figure of Nuit;
    say "Vous avez l'impression d'avoir vu bouger dans les ombres protégées par les arbres.".
    
Every turn during traque:
    if a random chance of 20 in 100 succeeds
        begin;
            choose a random row in Table of Stress;
            say "Vous avez l'impression d'avoir entendu [evenement entry].";
        otherwise;
            say "";
        end if.
    
The CCombat is a number which vary. The CCombat is 10.

Every turn:
    Now the CCombat is 10;
    if the armure is worn, increase the CCombat by 2;
    if the armure is not worn, decrease the CCombat by 1;
    if traque is happening, decrease the CCombat by 1;
    if the player is not carrying wakizashi, decrease the CCombat by 2;
    if the player carries katana, increase the CCombat by 3;
    if the katana is magic, increase the CCombat by 4;
    if the fantomes are in parvis, increase the CCombat by 3.
    
Understand "CCombat" as a mistake ("Votre capacité de combat est de [CCombat].").

Temple is a room in dedans. The description of Temple is "[if not visited]Après des jours de marche dans la forêt vierge avec votre compagnie, vous êtes enfin arrivé au temple de Susa-no-o, le dieu de la mer et des orages. Votre unité a été décimée sur les marches montant à ce lieu, mais vous avez réussi à vous glisser dans l'enceinte sacrée du temple, hors d'atteinte de vos ennemis. En tout cas cela ne veut pas dire qu'un de ces fourbes ne tentera pas de vous éliminer pour récupérer à votre place ce que vous êtes venu chercher ici. [end if]Le temple est une grande structure octogonale en bois, recouverte à l'intérieur de panneaux en palissandre. La plupart des décorations intérieures ont disparu au cours des temps, car ce temple a été abandonné durant plusieurs siècles et vraisemblablement pillé. La sortie se trouve au sud. [if player has katana][otherwise] Mais il n'est pas conseillé de sortir d'ici tout de suite, désarmé comme vous l'êtes. [end if]".

ChambreSacree is east from Temple. ChambreSacree is in dedans. The printed name of ChambreSacree is "Chambre sacrée". The description of ChambreSacree is "Cette pièce a conservé tous ses objets rituels, car elle était restée fermée sans que personne ne la découvre durant tout ce temps.".

Parvis is outside from Temple. Parvis is south from Temple.
Parvis is in dehors. The description of parvis is "L'entrée du temple se trouve en haut de quelques marches, mais ces marches sont actuellement tâchées du sang de vos compagnons qui sont tous tombés sous les coups de vos ennemis. En bas, tout autour du temple, une forêt qui semble sans fin. [if player has katana][otherwise] Vous ne devriez pas rester ici, car ils vous attendent également pour vous faire subir le même sort. [end if][if nuit is happening]Il fait nuit. [otherwise]Il fait jour. [end if]".

The DecorationInterieure is backdrop in Dedans.
The printed name of DecorationInterieure is "intérieur du temple". Understand "Intérieur du temple" or "toit du temple" or "interieur/toit/toiture/sol/tatami/poutres/temple" as DecorationInterieure. The description of DecorationInterieure is "Tout cet espace inspire à la méditation et au travail sur soi-même.".

The escalier is backdrop in parvis and in foret. Understand "sang/marches/marche/escalier" as escalier.
The description of escalier is "Les marches sont recouvertes du sang de vos compagnons."

Some compagnons are backdrop in dehors.
The description of compagnons is "Des samouraïs honorables, qui sont tombés sous le nombre et la ruse de vos ennemis de toujours, les ninjas du clan de Daimyo."

Some decorsdehors are backdrop in dehors. The printed name of decorsdehors is "des choses au dehors". The description of decorsdehors is "C'est juste des éléments du décor.". Understand "feuillage/palmiers/toit/temple/ombres/arbres" as decorsdehors.


Foret is down from Parvis. Foret is in dehors. Foret is outside from Parvis.
The printed name of Foret is "Forêt". The description of foret is "Une clairière dans la forêt.".

Instead of going down from Parvis during Nuit:
    say "Un samouraï évite toujours d'aller combattre durant la nuit, surtout si ses ennemis sont des adeptes des techniques et des combats nocturnes.".

Instead of going east from Temple when the scarabee is not in cachette, say "Vous ne pouvez pas aller par là."