Les Heures du vent
An interactive fiction by Eole (2007) - the Inform 7 source text
Contents
Previous
Next
Complete text
Manoir31 is scenery in Place31.
Understand "manoir/maison/porte/lierre/vigne/vierge" as Manoir31.
The description of Manoir31 is "On aurait pu s[']attendre à découvrir une telle bâtisse au fond d[']une forêt ou au sommet d[']une colline, néanmoins elle se trouvait au beau milieu de ce village, c[']était d[']ailleurs la plus haute construction des environs. De la vigne vierge et du lierre couraient sur les murs".
Instead of entering Manoir31, try going inside.
Instead of attacking Manoir31, try going inside.
Instead of opening Manoir31, try going inside.
The printed name of PlaceFontaine33 is "Place de la fontaine.".
The description of PlaceFontaine33 is "Il y avait là une fontaine, comme dans tous les villages et les villes de la région.".
The Fontaine33 is female scenery in PlaceFontaine33.
The printed name of Fontaine33 is "fontaine".
The description of Fontaine33 is "[if riviere is bouchee]La fontaine était à sec, ce qui était un peu étrange en cette période de l[']année. [otherwise]La fontaine coulait d[']une eau monotone mais sans doute rafraichissante. [end if]Sa margelle était richement sculptée et représentait des scènes de chasse et de vendanges. Au sommet trônait le blason du village.".
Understand "la/Fontaine/eau/roche/puits" or "la fontaine" as Fontaine33.
The PanneauFontaine33 is scenery in PlaceFontaine33. The printed name of PanneauFontaine33 is "blason".
Understand "blason/armorial/ours/soleil" as PanneauFontaine33.
Some 3clous are scenery in void. The printed name of 3clous is "trois clous". Understand "clous" as 3clous. [The undefinite article of 3clous is "les".]
The description of 3clous is "Trois clous maintenaient ce blason sur la fontaine, apparemment il en manquait un dans un des angles.".
Instead of taking or pulling or pushing 3clous, say "Ils étaient trop solidement ancré dans la roche de la fontaine.".
Instead of putting clou on PanneauFontaine33, say "Il avait sans doute mieux à faire avec ce clou plutôt que de se charger du travail des autres.".
Instead of examining PanneauFontaine33:
say "Parti, au premier de sinople à l[']ours de sable, au second de sable au soleil d[']or, chargé au comble d[']une potence et contrepotence d[']or. Le blason de la ville était fixé sur la fontaine par quelques clous, et sa devise resplendissait en lettres d[']argent : [italic type]'La force de l[']ours, l[']esprit du soleil['][roman type].";
display the figure of blason ours;
move 3clous to location.
The petit marteau is a thing.
Understand "lettres" as petit marteau.
The description of petit marteau is "Un petit marteau richement ouvragé, son manche était gravé de lettres dans une langue inconnue, peut-être était-ce de la moyenne-haute langue naine, ce qui aurait situé l[']outil comme ayant appartenu à un artisan ou un orfèvre.".
Instead of searching Fontaine33 for the first time:
say "Il aperçu [if riviere is not bouchee]dans l[']eau [otherwise]dans le bac désormais vide [end if]un petit marteau qui avait dû tomber là lors d[']une de ces foires où tout le monde se bousculait.";
move petit marteau to location.
Instead of drinking Fontaine33:
if riviere is bouchee
begin;
say "Le fontaine ne donnait plus d[']eau en ce moment.";
otherwise;
if riviere is polluee
begin;
say "L[']eau avait un goût un peu terreux, mais il continua a en boire un peu. Après quelques minutes, il sentit de violentes crampes à l[']estomac, et s[']effondra sur le sol. [if player is metamorphosable]Son corps affaiblit, il sentit alors qu[']il ne pouvait pas retenir un pouvoir qui était en lui, et il se transforma en animal sauvage. Ce sont les villageois parmi les moins médusés par cet étrange phénomène qui se sont chargés d[']abréger ses souffrances.[end if]".
end the game in death;
otherwise;
say "L[']eau était rafraichissante.";
end if;
end if.
Instead of smelling Fontaine33:
if riviere is bouchee
begin;
say "Le fontaine ne donnait plus d[']eau en ce moment.";
otherwise;
if riviere is polluee
begin;
say "L[']eau avait une odeur un peu déplaisante, mais difficilement définissable.".
otherwise;
say "L[']eau ne sentait rien de particulier, mais ses embruns étaient frais.";
end if;
end if.
[Instead of searching Fontaine33, try smelling Fontaine33.]
Instead of touching Fontaine33, try smelling Fontaine33.
The SculptureFontaine33 is part of the Fontaine33. [SculptureFontaine33 is female and scenery]
The printed name of SculptureFontaine33 is "sculpture".
Understand "cerf/chiens/scene/chasse/raisin/gens/margelle/sculpture/sculptures" as SculptureFontaine33.
The description of SculptureFontaine33 is "La partie gauche de la fontaine décrivait une partie de chasse à courre avec un cerf poursuivi par des chiens. La partie droite montrait des gens qui foulaient le raisin avec les pieds dans le but d[']en extraire le jus pour la préparation du vin.".
[TODO : ajoute memoire pour les scuptures]
The printed name of MaisonMagicien is "Maison".
Understand "couloirs/couloir/bureau/serviteur" as MaisonMagicien.[faire un objet specifique]
The description of MaisonMagicien is "[if location is not visited]Lorsqu[']il se présenta à la porte, un valet bien habillé l[']accueillit et le conduisit à travers un dédale de couloirs vers le bureau du magicien : il était attendu. Il arriva au seuil de l[']espace de travail de son ami, et il ne lui restait plus qu[']à avancer pour le rencontrer.[end if][if location is visited]Il n[']avait vu ici guère plus que les interminables couloirs pour arriver au bureau de son ami. Il lui semblait d[']ailleurs que le serviteur lui faisait emprunter un chemin différent à chaque fois...[end if]".
BureauMagicien is north from MaisonMagicien.
The printed name of BureauMagicien is "Bureau du magicien".
The description of BureauMagicien is "Si le labyrinthe de pièces qu[']il avait emprunté était relativement étrange, le capharnaum qui se trouvait dans ce lieu dépassait l[']entendement, c[']était à se demander si les angles de cette chambre répondaient aux lois de la physique.".
The magicien is a man in BureauMagicien. Understand "homme/ami/Buipilir/Builbesta" or "Buipilir Builbesta" as magicien. [TODO : nom Rhochruk]
The indefinite article of magicien is "le".
Instead of talking to Magicien for the first time during RencontreMagicien1:
change the name of the player to Zéphyr;
say "'Ah, Zéphyr, vous voilà mon ami. Merci d[']avoir répondu favorablement à mon appel. j[']espère que vous pourrez également accepter ma requête, qui, si elle n[']est en rien désespérée, me met dans une situation embarrassante. Vous connaissez sans doute le livre de Kalpertsil, un recueil de contes populaires inédits dont je possédais un exemplaire. Je lisais chaque soir un de ces contes à ma fille, Norja. Cet ouvrage m[']a été volé récemment, et j[']ignore qui est l[']auteur de ce forfait.'".
Instead of talking to Magicien for the second time during RencontreMagicien1:
say "Les deux hommes continuèrent de parler ainsi durant une partie de la matinée. Quelques soupçons furent évoqués, le premier au sujet du maire du village, un homme corrompu. Le second se portait vers une sorcière jalouse qui se trouvait à l[']extérieur du village. Mais aucune preuve tangible dans les deux cas. Il y avait également la possibilité de trouver un autre exemplaire de ce livre à la bibliothèque de la ville, mais le bibliothéquaire ne le prêterait sans doute pas volontier, à supposer que l[']ouvrage soit encore disponible là-bas. Enfin, cet ouvrage existant en trois ou quatre exemplaires, il devait être possible de le trouver chez un marchand ou ailleurs, bien entendu rien n[']était moins certain, car les volumes restant étaient peut-être détruits ou disparus à jamais.";
now the player is informed.
Instead of talking to Magicien for the third time during Matinee1, say "'Vous savez que je ne suis plus le jeune homme d[']avant, à pouvoir courir les plaines, les vallées et les montagnes. Norja et moi comptons sur vous pour retrouver ce livre inestimable. De plus, quand vous l[']aurez en main, vous verrez à quel point il est étrange et spécial.'"
Instead of talking to Magicien during Matinee1:
say "Les deux hommes n[']avaient plus rien de spécial à se dire pour le moment.".
Instead of giving the Livre_Conte1 to Magicien during Matinee1, say "'Merci à vous, mais ce n[']est pas cet ouvrage que j[']attendais. Je sais qu[']il n[']y a que vous qui puissiez tirer quelque chose de ce genre de livre, avec votre imagination, votre rhétorique, votre savoir-faire. Je suis un piètre conteur, et avec le livre de Kalpertsil c[']était bien différent...'"
Instead of giving the LivreSorcellerie to Magicien, say "Il lui conseilla, d[']un air triste : 'Ce triste simulacre de ce qui fut autrefois notre belle magie élémentaire n[']apporte jamais rien de bon à celui qui se fourvoie dans ses méandres. Son sang s[']obscurcit, son âme se voile tandis que son esprit ne lui appartient plus vraiment. Vous feriez mieux de vous en débarrasser au plus vite.'".
The printed name of PlaceSudVillage is "Partie sud du village".
The description of PlaceSudVillage is "Cette partie du village était dégagée et présentait quelques champs cultivés au sud. Un petit chemin longeait des maisons à l[']ouest.".
The domestique is a kind of person. The domestique can be male or female.
Instead of attacking a domestique:
say "Le domestique prit peur et s[']enfuit rapidement.";
remove valet from play;
remove servante from play.
The valet is a domestique. The valet is male. The description of the valet is "Cet homme portait un tricorne noir sur la tête, et des habits de deux couleurs uniquement."
Understand "valet/homme/tricorne" as valet.
The servante is a domestique. The servante is female. The description of the servante is "Cette femme gironde portait une coiffe blanche sur la tête, et des habits ternes. Elle avait l[']air énergique."
Understand "servante/femme/bonnet" as servante.