Les Heures du vent
An interactive fiction by Eole (2007) - the Inform 7 source text
Contents
Previous
Next
Complete text
Section 1 - La mairie
A person can be recognised or unknown. A person is usually unknown.
A room can be allowed or forbidden. A room is usually allowed.
Place31 is outside from MairieVillage.
The description of MairieVillage is "La mairie était un lieu assez sombre, les petites fenêtres cernées de plomb ne pouvant apporter beaucoup de lumière à la pièce principale. ". The printed name of MairieVillage is "Mairie du village".
MairieEtage is up from MairieVillage. The description of MairieEtage is "Ce niveau était refait à neuf, mais il n[']y avait pas grand chose à voir. Le sol était composé de tomettes en terre cuite rouge, et les murs étaient enduits à la chaux, comme dans beaucoup d[']habitations par ici. Une bibliothèque tapissait le fond de la salle, et un bureau se trouvait devant. Une ouverture menait vers une petite chambre à l[']ouest.". The printed name of MairieEtage is "Premier étage de la mairie".
The bibliothèque de la mairie is female scenery in MairieEtage. Understand "livres/bibliotheque" as bibliothèque de la mairie.
The bureau dans la mairie is scenery in MairieEtage.
Instead of searching bibliothèque de la mairie:
say "Ce n[']était pas de la grande littérature qui se trouvait là. Pas le moindre recueil de poésies du grand barde Kartrix le Narcissique, ni même l[']Épopée Chevaleresque des Grands Rois, compilée par Gormacyte le Valeureux. Juste d[']ennuyeux livres de comptes, des rapports d[']états majors, des cahiers de doléance et des registres d[']états-civils. [if LivreSorcellerie is in Void]Le livre recherché n[']était certe pas ici, par contre il se trouvait un ouvrage à la reliure noire, en cuir craquelé, qui détonnait un peu par rapport au reste.[end if]";
move LivreSorcellerie to location.
Instead of giving LivreSorcellerie to MaireCorrompu: say "L[']homme devint subitement rouge de colère, et cria à un garde qui passait là qu[']un adepte du malin était entré dans le village et qu[']il essayait de le corrompre avec de la littérature subversive et diabolique. Zéphyr fut emprisonné et exécuté rapidement après cet incident."; end the game in death.
Instead of giving LivreSorcellerie to Bailli: say "L[']homme prit l[']ouvrage, paru choqué par son contenu, et déclara qu[']il fallait détuire ce genre de subversion.".
MairieEtageChambre is west from MairieEtage. The description of MairieEtageChambre is "La chambre était petite et inconfortable. Un lit en désordre était posé à même le sol. ". The printed name of MairieEtageChambre is "Chambre à l[']étage".
The LitMairie is a scenery in MairieEtageChambre. Understand "lit/desordre/matelas" as LitMairie. The printed name of LitMairie is "lit". The description of LitMairie is "Il ne semblait pas avoir été utilisé depuis longtemps, car la couverture était pleine de poussière. Le maire devait certainement avoir sa maison ailleurs dans le village.".
The LitMairie is enterable and fixed in place.
Instead of searching LitMairie:
say "Il n[']y avait rien d[']intéressant ici, cela ne servait à rien de remuer toute cette poussière. Néanmoins, en y regardant mieux, il put voir une bougie près du lit.";
move bougie to location.
The bougie is a female device in Void. The printed name of bougie is "bougie noire".
Understand "bougie/cire/noire" or "bougie noire" or "cire noire" as bougie.
The description of bougie is "Une bougie en cire noire.".
Instead of switching on bougie, say "Il ne pouvait pas allumer cela : la bougie refusait de brûler, quelque puisse être ses efforts allant dans ce sens. Quel était ce sortilège ?".
Instead of burning bougie, try switching on bougie.
Instead of switching off bougie, say "La bougie n[']était pas allumée.".
The EtagereMairieEtageChambre is a female supporter in MairieEtageChambre. Understand "etagere" as EtagereMairieEtageChambre. The printed name of EtagereMairieEtageChambre is "étagère".
The farine is a female thing in Void.
The indefinite article of farine is "de la".
Understand "sac" as farine.
The marque is a female thing. It is not portable. The description of marque is "Une tâche noire et un peu brillante, formant une sorte d[']étoile.". Understand "tache" or "tache brune" or "marque brune" as marque.
The fiole is a female container in Void.
Understand "fiole transparente" or "mineraux" or "mineraux brillants" or "terre" or "recipient" as fiole.
The description of fiole is "Une minuscule fiole[if fiole is not open] scellée par un cachet en cire noire[end if]. On avait l[']impression qu[']il y avait un peu de terre et des minéraux brillant au fond du récipient.".
The cachet en cire noire is in fiole. [Understand "cachet en cire" or "cachet cire" as cachet en cire noire.]
Instead of opening fiole:
say "Le cachet semblait soudé à la fiole, mais en s[']échinant un peu il put casser la cire qui se réduisit en poussière.";
remove cachet en cire noire from play;
now fiole is open.
Instead of attacking cachet en cire noire, try opening fiole.
Instead of drinking fiole:
try opening fiole;
say "Lorsqu[']il porta la fiole a sa bouche, il eu l[']impression qu[']un formidable torrent lui entrait dans la gorge. Il sentit alors des rochers et un volume d[']eau infini l[']engloutir à jamais.";
end the game in death.
Instead of attacking fiole:
now the riviere is saine;
say "Le liquide en tombant fit une marque étrange, qui s[']estompa un peu par la suite.";
move marque to location;
remove fiole from play.
Instead of emptying fiole:
say "Il vida la fiole qui devint rapidement poisseuse et glissante. Elle lui échappa des mains et se cassa sur le sol.";
try attacking fiole.
The fiole can be discovered. The fiole is not discovered.
The fiole can be discoveredbybailli. The fiole is not discoveredbybailli.
Instead of showing fiole to VieilleFemme1, say "La vieille ricana en voyant cet objet. [if VieilleFemme1 is seduced]Elle lui raconta que cette fiole était un peu comme une dagyde, et qu[']elle servait à envoûter quelque chose.[end if]".
Instead of showing fiole to Bailli, say "Le bailli regarda cette fiole avec de gros yeux. Il demanda alors calmement qu[']on lui remette cet objet.".
RendrelaFioleBailli is a scene. RendrelaFioleBailli begins when the fiole is discoveredbybailli. RendrelaFioleBailli ends when the time since RendrelaFioleBailli began is 10 minutes.
Instead of giving fiole to Bailli:
say "Il prit la fiole mais celle-ci lui échappa des mains et en touchant le sol se cassa avec un petit bruit bref, laissant une légère marque sombre. Avec un petit sourire il haussa les épaules comme si cela n[']était rien, et continua ses affaires.";
now the riviere is saine;
move marque to location;
remove fiole from play.
FioleNonRendue rules is a rulebook.
A FioleNonRendue rule:
say "Une dizaine de gardes vinrent alors autour de Zéphyr[if player is carrying fiole], qui dû rendre de force la petit fiole[end if]. Il fut alors conduit en prison, et on n[']entendit plus jamais parler de lui.";
end the game saying "Perdu.".
FioleRendue rules is a rulebook.
A FioleRendue rule:
say "Une troupe d[']une dizaine de gardes s[']approcha de Zéphyr, ils le jaugèrent un moment comme pour essayer de l[']impressionner, puis repartirent ensuite sans s[']occuper plus de lui, en laissant éclater des rires gras et grossiers.".
When RendrelaFioleBailli ends:
if the Bailli is not carrying the fiole
begin;
follow the FioleNonRendue rules;
otherwise;
follow the FioleRendue rules;
end if.
Instead of asking bailli for fiole:
say "Il affirma qu[']il ne l[']avait plus.". [obsolete]
Instead of showing fiole to MaireCorrompu:
say "Le maire regarda l[']objet d[']un oeil distrait. Il déclara que c[']était sans doute sans importance et qu[']il fallait le remettre aux autorités.";
now the fiole is discovered.
Instead of giving fiole to MaireCorrompu:
say "Il s[']en empara avec avidité et la plaça dans une poche intérieure de sa veste.";
now MaireCorrompu is carrying the fiole.
RendrelaFioleMaire is a scene. RendrelaFioleMaire begins when the fiole is discovered. RendrelaFioleMaire ends when the time since RendrelaFioleMaire began is 10 minutes.
When RendrelaFioleMaire ends:
if the MaireCorrompu is not carrying the fiole
begin;
follow the fioleNonRendue rules;
otherwise;
follow the fioleRendue rules;
end if.
Instead of asking MaireCorrompu for fiole:
say "Il ne voulut pas rendre ce qui appartenait désormais aux autorités.".
Instead of throwing farine at vent: say "La farine se dispersa dans le vent, comme une puissance mauvaise qui se dissolverait et disparaîtrait à jamais dans les forces de la nature."; choose a blank row in the table of conte2_solutions;
change solutions entry to "affaiblir l[']ennemi en divisant ses forces"; say "[imagination of player] de lui-même divisant les forces maléfiques de l[']ennemi.";remove farine from play.
Instead of inserting farine into vent, try throwing farine at vent.
Instead of examining EtagereMairieEtageChambre for the first time:
say "Il y avait un petit sac de farine sur l[']étagère, ainsi qu[']une petite fiole transparente.";
move farine to EtagereMairieEtageChambre;
move fiole to EtagereMairieEtageChambre.
Instead of searching EtagereMairieEtageChambre, try examining EtagereMairieEtageChambre.
Instead of opening farine, try examining farine.
Instead of closing farine, try examining farine.
Instead of switching on bougie, say "Il ne put allumer cela : la bougie refusa de brûler.".
Instead of burning bougie, try switching on bougie.
Instead of switching off bougie, say "La bougie n[']était pas allumée.".
The petit tabouret is an enterable supporter in MairieEtageChambre. The petit tabouret is portable.
[todo : meubler cette piece]
The tapis is in MairieEtageChambre. Instead of looking under tapis, say "Il n[']y eu rien sous ce tapis, excepté un peu de poussière.".
[Instead of pushing petit tabouret, say "Il n[']avait que faire de ce tabouret !".
Instead of taking or pulling petit tabouret, try pushing petit tabouret.]
[Instead of sitting on petit tabouret, say "Il n[']était pas fatigué."]
Instead of going down when the player is on petit tabouret, try exiting.
Instead of going somewhere when the player has petit tabouret, say "Il ne voulait pas s[']encombrer à porter ce tabouret avec lui.".
Instead of going somewhere when the player has tapis, say "Il ne voulait pas s[']encombrer à porter cela avec lui.".
Instead of going up when in MairieVillage:
if bailli is in location
begin;
now MairieEtage is forbidden;
say "Cette partie du bâtiment n[']était pas réservée aux simples citoyens.";
otherwise;
move player to MairieEtage;
end if.