Les Heures du vent
An interactive fiction by Eole (2007) - the Inform 7 source text
Contents
Previous
Next
Complete text
The VieilleFemme1 is a female woman in CheminForet1. The printed name of VieilleFemme1 is "vieille femme". The description of VieilleFemme1 is "Une vieille femme habillée de hardes sans doute puantes.". Understand "vieille/sorciere/magicienne" or "femme" or "clocharde" as VieilleFemme1.
The indefinite article of VieilleFemme1 is "[if vieilleFemme1 is unknown]une[otherwise]la[end if]"
VieilleFemme1 hello, VieilleFemme1 divers, VieilleFemme1 weather, VieilleFemme1 VieilleFemme1, VieilleFemme1 voyage, VieilleFemme1 livre, VieilleFemme1 statues, VieilleFemme1 quete, VieilleFemme1 queteSolved and VieilleFemme1 Occultes are chat nodes.
Instead of talking to VieilleFemme1: run a conversation from VieilleFemme1 hello.
Instead of giving text for VieilleFemme1 hello: say "[if VieilleFemme1 is unknown]La vieille le remercia pour toute l[']aide passée, présente ou future qu[']il lui fournirait. [otherwise][end if]" ; now VieilleFemme1 is recognised. Instead of finding responses to VieilleFemme1 hello: link to VieilleFemme1 divers; link to VieilleFemme1 VieilleFemme1; link to VieilleFemme1 weather; if location is MaisonSorciere, link to VieilleFemme1 Occultes; link to VieilleFemme1 voyage; if the player is informed, link to VieilleFemme1 livre; if JardinForteresse is visited, link to VieilleFemme1 statues; if VieilleFemme1 is not seduced, link to VieilleFemme1 quete[; if VieilleFemme1 is seduced, link to VieilleFemme1 queteSolved].
Instead of giving link to VieilleFemme1 divers: say "Parler de tout et de rien". Instead of giving text for VieilleFemme1 divers: say "Des commérages, la vieille en connaissait. Mais pas du genre à être très informatifs. Il en appris un peu plus sur la femme du maréchal-ferrant et sur celle du boucher." ; deactivate VieilleFemme1 divers.
Instead of giving link to VieilleFemme1 VieilleFemme1: say "La questionner sur elle-même". Instead of giving text for VieilleFemme1 VieilleFemme1: say "Elle ne répondit rien." ; deactivate VieilleFemme1 VieilleFemme1.
Instead of giving link to VieilleFemme1 weather: say "Parler du temps". Instead of giving text for VieilleFemme1 weather: say "Le vent était fort un instant, faible à un autre." ; deactivate VieilleFemme1 weather.
Instead of giving link to VieilleFemme1 Occultes: say "Parler des mondes occultes". Instead of giving text for VieilleFemme1 Occultes: say "Elle lui raconta qu[']il y avait plusieurs manières pour visiter les mondes occultes, l[']une d[']entre elles pouvait être par un sommeil chamanique, une sorte de transe, une autre pouvait être par l[']envoûtement. Enfin, dit-elle en ricanant, il y avait également la mort qui était un moyen radical !".
Instead of giving link to VieilleFemme1 statues: say "Parler des statues près de la forteresse". Instead of giving text for VieilleFemme1 statues: say "Elle récita simplement cette comptine : [paragraph break][Contrerime des Statues]"; deactivate VieilleFemme1 statues.
Instead of giving link to VieilleFemme1 livre: say "Parler du livre de conte". Instead of giving text for VieilleFemme1 livre: say "La vieille femme répondit qu[']elle n[']avait jamais entendu parler de ce livre."; deactivate VieilleFemme1 livre.
Instead of giving link to VieilleFemme1 quete: say "Lui demander s[']il pouvait l[']aider d[']une manière ou d[']une autre". Instead of giving text for VieilleFemme1 quete: say "La vieille femme lui dit qu[']elle aurait bien aimé avoir une ou plusieurs bougies en cire pour s[']éclairer, les villageois qui ne l[']aimaient pas trop évitaient de faire du commerce avec elle. Elle souhaitait cela car les torches avaient tendance à faire trop de fumée. Elle avait bien une lampe à huile, auparavant, mais elle ne la retrouvait plus.".
Instead of giving link to VieilleFemme1 queteSolved: say "TODO". Instead of giving text for VieilleFemme1 queteSolved: say "TODO".
Instead of giving link to VieilleFemme1 voyage: say "L[']interroger sur ses activités".
Instead of giving text for VieilleFemme1 voyage: say "Elle lui répondit qu[']elle cueillait des plantes dans la forêt, préparait des décoctions, et allait les vendre aux gens du village ou de la ville un peu plus à l[']ouest, même si ceux-ci évitaient d[']avoir affaire avec elle, il semblait que cette femme avait un don pour trouver les bons remèdes." ; deactivate VieilleFemme1 voyage.
Instead of kissing VieilleFemme1, say "Il n[']en avait aucune envie !".
Instead of talking to VieilleFemme1 during VieilleFemmeCoule, say "Les mots seuls ne pouvaient pas lui être du moindre secours."
Instead of giving bougie to VieilleFemme1:
now the VieilleFemme1 is carrying the bougie;
now the VieilleFemme1 is seduced;
say "Elle le remercia pour son effort.".
Instead of giving bougie2 to VieilleFemme1:
now the VieilleFemme1 is carrying the bougie2;
now the VieilleFemme1 is seduced;
say "Elle le remercia pour ce présent.".
The salamandre is a woman. The description of salamandre is "Une vieille salamandre ridée, mais avec des taches d[']un jaune éclatant qui contrastaient avec le noir de sa robe. Ses yeux étaient pleins de vigueur et d[']audace.".
[The corde is a female thing in CheminForet1. [baton a la place]]
The tas de feuilles is an opaque container in OreeDuBois1. "Bien que ce lieu en fût empli, un tapis de feuilles, sur le sol, se détachait du reste, comme si elles avaient été manipulées il y a peu de temps." It is fixed in place.
Understand "feuilles/feuille" or "tapis de feuille" or "tas de feuille" as tas de feuilles.
Rule for printing the name of the tas de feuilles:
say "tapis de feuilles";
omit contents in listing.
The description of tas de feuille is "Il semblait avoir été remué récemment.".
[Instead of searching tas de feuilles, say]
The Baton is a weapon in tas de feuilles. The printed name of baton is "bâton". The description of baton is "Un bâton en bois de noisetier, assez flexible mais encore relativement nerveux pour en faire une arme redoutable dans des mains expertes. Il se souvenait avoir souvent utilisé du bois de ce type pour confectionner des arcs et des pièges durant sa jeunesse. ".
Understand "baton" and "badine" and "noisetier" as baton.
Before searching tas de feuille for the first time:
say "L[']endroit avait été fouillé récemment, sans succès apparemment car un bâton se trouvait toujours là.";
continue the action.
Instead of attacking baton, say "Ce genre de bois plie mais ne rompt pas.".
After taking the baton for the first time:
choose a blank row in the table of conte2_heros;
change heros entry to "d[']un jeune garçon";
choose a blank row in the table of conte2_destinations;
change destinations entry to "dans la forêt";
say "[imagination of player] d[']un jeune garçon qui jouait dans la forêt.";
continue the action.
Instead of attacking VieilleFemme1:
if VieilleFemme1 is in Riviere1
begin;
if the player has a weapon
begin;
choose a blank row in the table of conte2_problemes;
change problemes entry to "était devenu injuste";
choose a blank row in the table of conte2_ennemis;
change ennemis entry to "de son propre chaos intérieur et d[']objets emplis de pouvoir";
say "[imagination of player] de lui-même devenant injuste.[line break]";
say "Mû par des pensées folles, il leva son arme et la frappa alors qu[']elle était sans défense. La vieille femme et tous ses secrets disparurent à jamais dans l[']eau trouble de la rivière.";
move VieilleFemme1 to Void;
otherwise;
say "Il n[']eut pas d[']idées pour concrétiser cet acte, ni surtout le coeur à cela.";
end if;
otherwise;
say "Il découvrit que la vieille femme avaient beaucoup plus de ressources qu[']il n[']y paraissait. Un éclair jaillit de sa main ridée, foudroyant instantanément ce fou.";
end the game in death;
end if.
Instead of attacking VieilleFemme1 with a weapon, try attacking VieilleFemme1.
Before giving the baton to VieilleFemme1 when VieilleFemme1 is in Riviere1:
say "S[']approchant le plus possible des bords glissants de la rivière, il tendit à bout de bras le bâton à la vieille qui s[']en empara, et elle put ainsi remonter sur la berge.";
move VieilleFemme1 to location;
move baton to VieilleFemme1;
choose a blank row in the table of conte2_heros;
change heros entry to "d[']une vieille et pauvre femme";
choose a blank row in the table of conte2_problemes;
change problemes entry to "avait perdu pied";
choose a blank row in the table of conte2_solutions;
change solutions entry to "trouver une âme généreuse qui pu apporter son aide";
say "[imagination of player] d[']une vieille femme à l[']allure singulière se battant pour rester en vie.";
stop the action.
Before asking VieilleFemme1 for baton:
say "Elle lui dit que ce bâton appartenait à sa famille depuis de nombreuses générations, et qu[']elle ne désirait pas s[']en séparer.";
stop the action.
After examining location when VieilleFemme1 had been in location, say "La vieille n[']était plus là, était-ce une nouvelle sorte de sorcellerie ?". [ne fonctionne pas]
The description of OreeDuBois1 is "L[']entrée de la forêt était un havre de paix séparant les plaines battues par le vent et le coeur de la forêt qui demeurait assez inquiétant.". The printed name of OreeDuBois1 is "L[']orée de la forêt".
The description of GrandeForet1 is "Cette partie de la forêt devenait de plus en plus sombre. L[']unique chemin, le seul qui semblait suffisamment sûr en tout cas, traversait ce bois d[']est en ouest.". The printed name of GrandeForet1 is "Dans la forêt".
Instead of listening when the location is GrandeForet1 or GrandeForet2, say "Des bruits lugubres et indéfinissables surgissaient des hautes frondaisons des arbres ou des fourrés lointains.".
[TODO : scenery fourrés et arbres]
A GrandSapin1 is a thing in GrandeForet1. The printed name of GrandSapin1 is "grand sapin". Understand "arbre" or "sapin" or "pin" as GrandSapin1.
The description of GrandeForet2 is "La partie à l[']est de la forêt contenait des arbres plus denses. La zone était également plus humide, presque angoissante[if not visited]. Il sentit malgré tout le froid traverser la protection des arbres, et le vent lui voler sa chaleur corporelle. Cet endroit était glauque, et des cris d[']oiseaux qui n[']étaient pas visibles n[']arrangèrent rien, survenant aux moments où il s[']y attendait le moins[end if].". The printed name of GrandeForet2 is "Dans la forêt".
Some arbres are backdrop. It is in OreeDuBois1, OreeDuBois2, GrandeForet2 and GrandeForet1. [todo : descr arbres]
The description of OreeDuBois2 is "La forêt devenait plus lumineuse lorsque l[']on s[']approchait de son entrée, malgré les lourds nuages gris qui couvraient le ciel à l[']extérieur.". The printed name of OreeDuBois2 is "L[']orée de la forêt".