Les Heures du vent
An interactive fiction by Eole (2007) - the Inform 7 source text
Contents
Previous
Next
Complete text
The fou is a man in Montagne1. The description of fou is "[if fou is unknown]Un homme a l[']air hébété. [otherwise]Le fou. [end if]".
Understand "homme" as fou.
After examining the fou for the first time:
now the fou is recognised.
Chute du fou rules is a rulebook.
Before going west when in Montagne1:
if the former location is CheminMontagne1, continue the action;
if the former location is Ravin and the fou is in location
begin;
say "L[']homme lui bloqua le passage en gesticulant et agitant les bras dans tous les sens, tout en maugréant et proférant des propos insultants.";
stop the action;
end if.
Before going east when in Montagne1:
if the former location is Ravin, continue the action;
if the former location is CheminMontagne1 and the fou is in location
begin;
say "L[']homme lui bloqua le passage en gesticulant et agitant les bras dans tous les sens, tout en maugréant et proférant des propos insultants.".
stop the action;
end if.
A Chute du fou rule:
remove fou from play;
now the fou is dead;
choose a blank row in the table of conte2_ennemis;
change ennemis entry to "d[']un fou";
choose a blank row in the table of conte2_solutions;
change solutions entry to "modifier un certain point d[']appui pour en trouver un plus favorable à l[']équilibre du monde";
say "[imagination of player] d[']un homme habité par l[']arbitraire et le chaos qui avait trouvé un nouvel équilibre.".
Instead of throwing farine at fou:
remove farine from play;
say "Il jeta la farine dans les yeux du fou, qui, aveuglé, perdit encore plus ses moyens, et chuta dans le vide.";
follow the Chute du fou rules.
Instead of attacking fou:
say "Il frappa le fou mais la distance étant trop proche, ce dernier s[']aggripa à lui et ils chutèrent tout deux dans le vide.";
end the game in death.
Instead of pushing fou, try attacking fou.
[todo : tester location]
Instead of attacking fou with a weapon:
say "Il frappa le fou qui chuta dans le vide.";
follow the Chute du fou rules.
To say HuileFou:
say "Il répandit l[']huile sur le sol au moment où le fou se précipitait vers lui, ce dernier glissa et chuta dans le vide.".
[bidon et lampe huile]
Instead of pouring a ContainerHuile (called RecipientHuile) into sol when the location is Montagne1 and fou is in location:
if RecipientHuile is not empty
begin;
say "[HuileFou]";
now the RecipientHuile is empty;
follow the Chute du fou rules;
otherwise;
say "[recipient huile vide]";
End if.
Instead of pouring a ContainerHuile (called RecipientHuile) into fou when the location is Montagne1:
try pouring RecipientHuile into sol.
Instead of attacking fou with a ContainerHuile (called RecipientHuile) when the location is Montagne1:
if the RecipientHuile is not empty
begin;
say "[HuileFou]";
now the RecipientHuile is empty;
otherwise;
say "Il jeta [the RecipientHuile] au visage du fou, et celui-ci perdit tout contrôle de lui-même et chuta dans le vide.";
remove RecipientHuile from play;
end if;
follow the Chute du fou rules.
Instead of attacking fou with petit marteau, try attacking fou.
Instead of going down when in Montagne1, say "La descente était trop dangeureuse.".