Les Heures du vent
An interactive fiction by Eole (2007) - the Inform 7 source text
Contents
Previous
Next
Complete text
The description of Marais1 is "[if not visited]Il n[']était plus possible de savoir si c[']était le crépuscule, les nuages ou l[']obscurité naturelle de ce lieu qui le rendait aussi sombre. [end if]Cette vallée avait des zones très humides, entourées de souches et d[']arbres morts, et d[']autres plus vivables. Malgré tout, cela restait un endroit inhospitalier.".
The printed name of Marais1 is "Dans la vallée marécageuse".
Some souches are scenery in Marais1. Understand "arbres morts" as souches.
The description of DomaineSorciere is "[if not visited]Ce lieu semblait avoir vécu hors des saisons, il était moins humide que le reste, mais en contrepartie une neige fine avait recouvert tout ce qui était resté ouvert au ciel. [end if]Une petite maison se trouvait là. ". [TODO.]
The printed name of DomaineSorciere is "Un domaine oublié".
The neige is female scenery in DomaineSorciere.
The boule de neige is female containerEau in Void. Instead of examining boule de neige, say "Il n[']y avait rien à signaler sur cette boule de neige, froide, fondante, oscillant entre l[']élément solide et l[']élément liquide.".
Instead of inserting something into boule de neige, say "On ne pouvait rien mettre dedans, à part un peu de malice avant de la projeter sur quelqu[']un".
Instead of throwing boule de neige at someone:
remove boule de neige from play;
say "Manqué !".
Instead of taking neige when the player is human-being:
move boule de neige to player;
say "Il fit une petite boule de neige et la garda en main.".
NeigeFondante is a recurring scene. NeigeFondante begins when the boule de neige is carried by the player.
NeigeFondante ends when the time since NeigeFondante began is 15 minutes.
When NeigeFondante ends:
remove boule de neige from play;
say "La boule de neige [one of]fondit rapidement[or]redevint de l[']eau[or]fondit et disparu[at random].".
MaisonSorciere is inside from DomaineSorciere.
The printed name of MaisonSorciere is "À l[']intérieur de la chaumière".
The description of MaisonSorciere is "Il régnait dans ce lieu un capharnaüm indescriptible. Des pots renversés, contenant des substances douteuses, des sacs d[']herbes séchées, des grimoires maléfiques, le tout recouvert abondamment de poussière et de toiles d[']araignées. Ces dernières devaient avoir fui depuis longtemps un endroit aussi peu hospitalier[if vieilleFemme1 is in location][otherwise], en tout cas il n[']y avait pas là âme qui vive[end if].".
The soupe is female thing in MaisonSorciere. Soupe is edible.
The indefinite article of soupe is "de la".
Instead of drinking soupe, try eating soupe.
Instead of smelling soupe, say "Une bonne odeur de pommes de terre, de fromage, de bouillon, d[']épices et d[']aromates.".
The potion is female edible thing in Void. Instead of eating potion, try drinking potion.
Understand "tisane" as potion.
Instead of smelling potion, say "Cela sentait une odeur de plantes et de forêt : de la terre, des feuilles, des racines, des écorces, tout cela à la fois. Ce n[']était pas si désagréable.".
Instead of tying baies noires to soupe:
say "Il mélangea les baies noires dans la soupe.";
move potion to location;
remove baies noires from play;
remove soupe from play.
Instead of tying soupe to baies noires, try tying baies noires to soupe.
Instead of drinking potion:
now the player is metamorphosable;
remove potion from play;
say "La mixture lui brûla la gorge. Il senti alors des picotement dans tous ses membres et tomba comme en léthargie sur le sol. Il eu alors la vision de lui-même courant dans une forêt brumeuse, transformé en loup. Il se réveilla peu après.". [ (TODO).]
Instead of jumping when the player is metamorphosable:
now the player is metamorphosed;
change the name of the player to Le Loup; [inutile ici, attrapé par autre routine...]
now the player is not metamorphosable;
say "Au prix d[']un immense effort de concentration, il se visualisa en train de courir dans des plaines enneigées. C[']est alors qu[']il se transforma réellement alors en loup. Il n[']avait plus rien en main, ses pattes ne pouvant agripper des objets."; [(TODO).]
now every thing carried by the player is in the location.
[silently try dropping soupe.]
[
move the things carried by the player to location.
]
Instead of jumping when the player is metamorphosed:
now the player is human-being;
change the name of the player to Zéphyr;
now the player is metamorphosable;
say "Au prix d[']un immense effort de concentration, il se visualisa en train de préparer un feu de bois et de l[']allumer. C[']est alors qu[']il redevint un homme.". [(TODO).]
Instead of examining the lune when the player is metamorphosable, try jumping.
The capharnaüm is scenery in MaisonSorciere.
Understand "capharnaum/substances/sacs/herbes/grimoires/livres/poussiere/toiles/araignees" or "substances douteuses" or "sacs d'herbes sechees" or "grimoires malefiques" as capharnaüm.
Instead of searching capharnaüm for the first time, say "Il ne trouva rien, mais peut-être cela valait-il la peine d[']examiner plus attentivement les pots un peu plus loin...".
The pots are scenery in MaisonSorciere. Understand "pots renverses" as pots.
RencontreSorciere2 is a scene.
RencontreSorciere2 begins when the player is in MaisonSorciere for the first time.
RencontreSorciere2 ends when the time since RencontreSorciere2 began is 4 minutes.
When RencontreSorciere2 ends:
if the VieilleFemme1 is not in void,
say "La vieille femme arriva de son pas alerte. Elle se planta devant Zéphyr et le toisa de son regard sec. Elle lui proposa alors [if location is MaisonSorciere]de prendre une tisane[otherwise]d[']entrer prendre une tisane[end if]. TODO.";
Move VieilleFemme1 to MaisonSorciere;
Move Potion to MaisonSorciere;
Now the printed name of potion is "tisane".
The lampe à huile is female ContainerHuile in Void.
Understand "lampe" or "lampe a huile" as lampe à huile.
The lampe à huile is full.
The virole is a female device in lampe à huile. The description of virole is "Ce qui permettait d[']allumer la lampe.".
After printing the name of lampe à huile: omit contents in listing.
Before switching on virole:
if lampe à huile is full
begin;
say "[if lampe à huile is not lit]Il alluma la lampe, qui émit une douce lueur orangée.[otherwise]La lampe était déjà allumée.[end if]";
now the lampe à huile is lit;
now the virole is switched on;
stop the action;
otherwise;
say "La lampe ne contenait plus d[']huile.";
stop the action;
end if.
Before switching off virole:
if lampe à huile is lit
begin;
now the lampe à huile is not lit;
say "Il éteignit la lampe.";
now the virole is switched off;
stop the action;
otherwise;
say "La lampe était déjà éteinte.";
stop the action;
end if.
Instead of switching on lampe à huile, try switching on virole.
Instead of switching off lampe à huile, try switching off virole.
The description of lampe à huile is "[if lampe à huile is full]La lampe à huile était pleine d[']huile[otherwise]La lampe à huile était vide[end if]."
Instead of emptying lampe à huile:
if lampe à huile is full
begin;
say "Il vida la lampe, l[']huile se répandit sur le sol.";
now lampe à huile is empty;
otherwise;
say "Cette lampe était déjà vide.";
end if.
Instead of searching pots for the first time:
say "Il trouva une lampe à huile un peu abimée derrière une rangée de pots.";
Move lampe à huile to location.
Instead of examining pots, try searching pots.
Instead of tying lampe à huile to bidon, say "Cela n[']utilisait pas la même huile.".
Instead of tying bidon to lampe à huile, try tying lampe à huile to bidon.
Instead of pouring bidon into lampe à huile, try tying lampe à huile to bidon.
The MaisonSorciereFake is female scenery in DomaineSorciere. The printed name of MaisonSorciereFake is "chaumière". Understand "maison/chaumiere/baraque/batisse/chalet/hutte" as MaisonSorciereFake.
Instead of entering MaisonSorciereFake, try going inside.
The souche is female container in DomaineSorciere. The souche is fixed in place.
[
The barre de métal is female in DomaineSorciere.
Instead of forging barre de métal, say "Il forgea la barre de métal pour en faire une épée (TODO).".]
[todo : sorciere si elle est là, prend la bougie, sinon autre chose à faire]