Les Heures du vent
An interactive fiction by Eole (2007) - the Inform 7 source text
Contents
Previous
Next
Complete text
Chapter 1 - Le moulin
The description of CheminVille1 is "La route montant entre le village et la ville était relativement dégagée, présentant seulement quelques arbres disséminés ça et là. [if not visited] Une bourrasque siffla plus brutalement que tout le reste, mais retomba rapidement. [end if]La ville se trouvait plus loin vers l[']ouest, mais elle n[']était pas visible d[']ici, par contre le moulin du village, qui imposait sa silhouette massive sur la plaine, avait été construit au nord de cette route[if the histoire is à la fin]. Le moulin n[']était plus affecté par le vent, mais une grande onde semblait l[']agiter, comme une aura qui l[']entourait sur plusieurs centaines de mètres[end if]. ".
The printed name of CheminVille1 is "Chemin vers la ville."
The tag of CheminVille1 is "le chemin entre la ville et le village."
After deciding the scope of the player while in Moulin: place the CheminVille1 in scope.
After deciding the scope of the player while in CheminVille1: place the RelaisVille in scope.
After deciding the scope of the player while in RelaisVille: place the CheminVille1 in scope.
MoulinFake is scenery in CheminVille1. The description of MoulinFake is "Le moulin du village ressemblait à un donjon sur lequel on avait ajouté quatres grandes pales. Du fait de la force du vent, qui pouvait être aussi brusque que soudaine, des renforts avaient été disposés autours des voiles et sur la structure du moulin. L[']ensemble avait également été couplé à un moulin à eau qui se trouvait sous la tour, mais que l[']on pouvait un peu aperçevoir, dans un arrangement étrange et surréel.".
The AuraMoulin is scenery. The AuraMoulin is female. The description of AuraMoulin is "Une sorte d[']onde verte qui entourait le moulin.".
Understand "aura" as AuraMoulin.
The Riviere2 is female backdrop. It is in CheminVille1 and MoulinAube and RuePavee41 [sortie ouest] and PlaceSudVillage. The printed name of Riviere2 is "rivière". The indefinite article of riviere2 is "la".
The description of riviere2 is "La rivière passait par la ville à l[']ouest, sous le moulin, sous le village, dans la forêt, et allait se jeter dans la mer vers l[']est.".
Understand "riviere/eaux/eau" or "de l~eau" or "l~eau" or "fleuve" as Riviere2.
Understand "suivre [Riviere2]" as a mistake ("Le cours d[']eau ne passait pas par des endroits praticables à pied, aussi il dut renoncer à cette idée.").
Understand "Moulin/pales/renforts" or "moulin a vent" or "moulin a eau" as MoulinFake. The printed name of MoulinFake is "moulin".
Instead of entering MoulinFake, try going north.
The description of Moulin is "[if not visited]Le château des petites gens, une construction solide et fortifiée pour résister aux vents, dans laquelle les villageois avaient pu se réfugier durant les guerres passées. Il monta la petit butte pour atteindre le moulin. [end if][if Partie2 is happening and riviere is not bouchee and location is not visited]Tandis qu[']il était encore à couvert derrière un petit bosquet d[']arbustes avant d[']atteindre la bâtisse, il vit le bailli qui sortait du moulin, visiblement essoufflé et ses habits couverts de terre. Celui-ci ne le vit heureusement pas, et repartit d[']un pas rapide en direction du village. [end if]Ce moulin à vent du village avait la particularité d[']être fortifié, pour le rendre indestructible face au courrou des vents. Son autre particularité était d[']avoir un second moteur, hydraulique cette fois, non seulement pour pouvoir freiner la vitesse des pales en cas de grand vent, mais surtout pour disposer d[']une énergie constante lorsque la saison n[']était plus propice aux vents. À l[']intérieur il y avait une échelle pour monter au premier étage, ainsi que quelques marches pour descendre au sous-sol.". [(TODO) descript / explication]
The bailli can be discovered. The bailli is not discovered.
Before going north from CheminVille1 for the first time:
[say "Bouché ! (TODO).";]
now the riviere is bouchee;
now the bailli is discovered;
move the bailli to PlaceSudVillage;
continue the action.
Some marches are female scenery in Moulin. Instead of climbing marches, try going down.
Instead of going outside from Moulin, try going south.
The échelle is female scenery in Moulin. Instead of climbing échelle, try going up.
Understand "echelle" as échelle.
The portail is a container. The portail is open.
Understand "flammes/flamme" as portail.
The description of portail is "Ce portail n[']avait pas de limites précises, il semblait se surimprimer sur l[']air ambiant. On avait l[']impression que des flammes brûlaient à l[']intérieur.".
Instead of entering portail:
say "Il était entré dans ce monde d[']un étrange façon, mais il en ressortira d[']une manière encore plus spéciale.";
end the game in death.
The description of MoulinHaut is "L[']étage du moulin était bien poussiéreux. Il n[']y avait plus que des planches cassées ou vermoulues et des sacs vides ici.". The printed name of MoulinHaut is "L[']étage du moulin". [todo descript]
The description of MoulinBas is "La pièce était tellement humide que l[']on aurait pu y faire pousser des champignons. ". The printed name of MoulinBas is "Le sous-sol du moulin". MoulinBas is a dark room.
Some SacsVides are scenery in MoulinHaut. Understand "sac/sacs" or "sacs vides" as SacsVides.
The printed name of SacsVides is "sacs vides".
Some VieillesPlanches are scenery in MoulinHaut. Understand "planche/planches" or "vieilles planches" or "planches cassées" or "planches vermoulues" as VieillesPlanches.
The printed name of VieillesPlanches is "vieilles planches".
The description of MoulinAube is "Cette pièce souterraine contenait le coffre de la roue à aube qui tournait derrière.". The printed name of MoulinAube is "La salle des machines". MoulinAube is a dark room.
The coffreRoueAube is scenery in MoulinAube. The printed name of CoffreRoueAube is "coffre de la roue à aube". Understand "coffre/roue/bitume" or "roue a aube" as CoffreRoueAube. The description of CoffreRoueAube is "Un coffre en bois, de la forme de la roue, et calfalté avec du bitume pour en assurer l[']étanchéité.".
[todo : faire qque chose avec du bitume : allumer bitume etc]
The lucarne is female container in MoulinAube. It is fixed in place. Understand "trou/mechanisme" as lucarne. Instead of examining lucarne, say "Cette lucarne se trouvait en bas du mur, sous le coffre en bois. Elle faisait deux pieds de large et presque autant de haut.".
The Rocher2 is a thing in void. Understand "rocher" as rocher2. The printed name of rocher2 is "rocher".
The manche is a weapon in void. Understand "outil" as manche.
[The vanne is female scenery in MoulinAube. ]
The conduit is scenery in MoulinAube.
Instead of searching conduit, say "Il n[']était pas accessible, de plus il était généralement rempli d[']eau.".
Instead of searching lucarne:
if riviere is bouchee
begin;
if rocher2 is in void, move Rocher2 to lucarne;
if manche is in void, move manche to lucarne;
say "Il vit une partie du méchanisme du moulin, totalement inaccessible[if rocher2 is in lucarne], ainsi qu[']un gros rocher qui avait été poussé devant un conduit d[']évacuation[end if][if manche is in lucarne], et il y avait aussi un manche d[']outil qui bloquait la roue, l[']empêchant de décupler le débit de la rivière[end if]."; [ TODO. descript]
otherwise;
say "Il n[']y avait rien à signaler ici.";
end if.
Instead of touching rocher2 for the first time:
move rocher2 to location;
say "Il retira le rocher de devant l[']évacuation, et une partie de l[']eau s[']y engouffra. Il pu ainsi sortir la grosse pierre par la lucarne.".
Instead of taking rocher2:
say "Il était trop lourd pour le transporter. Néanmoins, il pouvait le bouger de place en le tirant vers lui. ";
try touching rocher2.
Instead of pulling rocher2 when rocher2 is in location, say "Il n[']eut pas besoin de le déplacer plus loin, l[']évacuation était déjà dégagée.".
Instead of pushing rocher2, say "Il fallait retirer ce rocher, pas l[']enfoncer davantage.".
Instead of pushing rocher2 when rocher2 is in location, try pulling rocher2.
Instead of taking manche for the first time:
say "Il tira sur l[']outil qui était coincé dans la roue, et celui-ci se débloqua subitement, laissant Zéphyr atterrir sur son postérieur, et le manche traverser la pièce brusquement. Il se releva, un peu vexé par cette chute honteuse."; [(TODO) ameliorer description]
move manche to location.
[todo si possible : la lumiere s[']eteind]
Instead of pulling manche, try taking manche.
Every turn when in MoulinAube:
if riviere is bouchee
begin;
if rocher2 is in MoulinAube and manche is in MoulinAube
begin;
now riviere is not bouchee;
say "La rivière sembla couler de nouveau correctement à partir de ce moment.";
otherwise;
do nothing;
[say ".";]
end if;
otherwise;
do nothing;
end if.
Instead of listening while in moulinAube,
say "Le son de la rivière semblait étouffé et troublé."
[creer une scene pour riviere bouchee car bug]
RiviereBouchee is a scene.
RiviereBouchee begins when riviere is bouchee.
RiviereBouchee ends when riviere is not bouchee.
RiviereEmpoisonnee is a recurring scene.
RiviereEmpoisonnee begins when riviere is polluee.
RiviereEmpoisonnee ends when riviere is saine.
Every turn during RiviereEmpoisonnee:
if the location is village
begin;
say "[one of]Il entendit des rumeurs comme quoi l[']eau était imbuvable.[or]Il entendit des gens se plaindre de la qualité déplorable de l[']eau.[or]Certains villageois semblaient fort malades ou bien abattus.[or]Les gens disaient que les ennemis étaient déjà dans la région et avaient empoisonné les sources d[']eau potable.[or]Il remarqua que certains passants avaient une bien mauvaise mine.[or] [or] [or] [or] [or] [or] [stopping]";
end if.
Every turn during RiviereBouchee:
if the location is village
begin;
say "[one of]Il entendit dire qu[']il n[']y avait plus d[']eau dans le village.[or]Il entendit des gens se plaindre du manque d[']eau.[or] [or] [or] [or] [or] [stopping]";
end if.
Instead of pulling rocher2, try touching rocher2.