Sarvegne
An interactive fiction by Eric Forgeot (2006) - the Inform 7 source text
Contents
Next
Complete text
Dehors is a region. Sentier, Sentier2, EntreeVille, DerriereVille, DerriereVille2, DerriereVille3, DevantPorteVille and DerriereVille4 are in Dehors.
Arrivee is a scene. Arrivee begins when the player is in Sentier for the first turn. Arrivee ends when the player is in bibliotheque for the first turn.
Rencontre is a scene. Rencontre begins when the player is in bibliotheque for the first turn.
[RendezVous is a backdrop. Rendezvous is everywhere. Rendezvous is scenery.]
[Understand "rendez-vous/rendez vous" as RendezVous. Instead of examining RendezVous, say "Vous ne pouvez le voir, mais peut-être pouvez-vous y penser..."]
[Thinking is being pensif.
Understand the command "penser [text]" as think.]
Instead of thinking during arrivee, say "Vous avez rendez-vous avec une jeune fille qui s'appelle Anita. Vous ne l'avez jamais rencontrée, mais vous savez qu'elle pourra vous aider.[line break]"
Instead of thinking in DerriereVille, say "Vous vous rappelez lorsque vous passiez près du grand mur gris de votre école. Votre mémoire a particulièrement imprimé l'éclat de la neige qui contrastait avec la grisaille du mur. Ensuite vous êtes reparti vers le sud et c'est la poussière du désert qui a remplacé la neige. Mais Sarvegne est une belle oasis au milieu de ces espaces arides.[line break]"
Instead of thinking in Dehors: [location in Ville:]
if Bibliotheque is not visited, say "Votre contact dans cette ville est une jeune fille qui travaille au conseil du Margrave. Vos divers échanges épistolaires ont permis de vous familiariser un peu avec elle, mais comment sera la réalité ? Elle vous a demandé de la rejoindre, mais n'a pu vous laisser qu'une adresse imprécise où vous pourriez la trouver.[line break]".
[When thinking to rendezvous during arrivee, say "Vous avez rendez-vous avec une jeune fille qui s'appelle Anita. Vous ne l'avez jamais rencontrée encore, mais vous savez qu'elle pourra vous aider par la suite."]
Instead of listening to Dehors, say "Le vent, le bruit de la nature, parfois quelques oiseaux que vous ne pouvez même pas voir..."
[unix is a backdrop.] unix is in bibliotheque. unix is scenery. The printed name of unix is "unix". Understand "unix/linux/freebsd/openbsd/netbsd/solaris/polaris" as unix.
The description of unix is "Le système unix est un standard dans l'informatique de la confédération, on le retrouve dans tous les appareils embarqués, les serveurs, ainsi que les ordinateurs personnels.[if player has calculateur and calculateur is switched on]Le noyau du système que vous avez sous les yeux affiche 'Polaris Kernel 4.84 smp 20 cores, 03/02/26 release'.[end if]".
ville_scenario is in dehors. The printed name of ville_scenario is "des détails de la ville". Ville_scenario is a backdrop. Understand "sentier/chemin/ville/tours/tour/statues/statue/muraille/murailles" as ville_scenario.
Instead of examining ville_scenario when in dehors, say "Votre chemin vous conduira immanquablement à la ville et ses constructions étonnantes. Vous devriez avant tout essayer d'y entrer le plus vite possible.".
soleil is in dehors. The printed name of soleil is "soleil". Soleil is a backdrop. Understand "soleil/orange/vert" as soleil.
Instead of examining soleil when in dehors, say "Il y a deux soleils dans le ciel, l'un est orange, l'autre est vert.".
Instead of examining soleil when in ville, say "Les soleils donnent des teintes étranges mais agréables aux bâtiments de la ville.".
Sentier is a room. The printed name of Sentier is "Sentier". "Le sentier où vous vous trouvez mène vers la ville."
The Sentier has a number called nbvisite. nbvisite is 1.
Instead of examining the Sentier for the second time, say "Au loin, vers le nord, vous voyez l'aura d'une ville qui vous attire depuis de nombreuses années : Sarvegne.[line break]"
Before looking in sentier:
if sentier2 is not visited
begin;
display the Figure of lettrage;
[ display the Figure of titre;]
say "[line break]Votre voyage fut très long. Mais vous voilà enfin en route vers la mystérieuse cité qui est le but de votre voyage. Au loin, vers le nord, vous percevez l'aura de cette ville qui vous attire depuis de nombreuses années : Sarvegne.[line break]";
Otherwise;
say "Vous êtes sur un petit chemin peu fréquenté.";
end if;
Sentier3 is south of Sentier.
[TestRoom is east of Sentier.
the objet1 is here. The objet2 is here. The objet3 is here. The table is here. The table is a female supporter. ]
Sentier2 is north of Sentier. The printed name of Sentier2 is "Au bout du chemin.". "La ville est encore à une certaine distance, mais ses contours se font plus précis. L'atmosphère de cette région désertique est fraîche et pure, et le soleil un peu voilé ne vous affecte pas. Vous pouvez presque apercevoir les tours de la ville, mais elles restent toujours indistinctes. [line break]Plus proche de vous, à quelques pas, vous pouvez voir un buisson encore assez vert.".
After going in sentier2:
if sentier2 is not visited
begin;
say "Ce chemin serpente doucement pour vous rapprocher de votre destination. Un certain nombre de routes mènent à Sarvegne, mais celle que vous avez empruntée n'est pas la plus utilisée. Après avoir quitté votre famille vous avez pris une navette rapide pour vous conduire à l'aérogare la plus proche. Il n'était alors pas possible d'entrer dans la ville directement, pour des raisons que vous ignorez encore."; continue the action;
Otherwise;
say ""; continue the action;
end if;
The buisson is scenery in sentier2. The buisson is a container.
The cube is in buisson.
A thing has a number called charge. The charge of a thing is usually 0.
instead of examining cube:
if player is in sentier2 and cube is not in player then say "Le cube est couvert de la poussière du sol.";
if charge of the cube is less than 1 then say "Le cube semble vide et froid.";
otherwise say "Le cube semble chargé d'une énergie puissante.".
After taking cube:
if player is in sentier2 then say "C'est un cube de métal qui se trouvait sur le bord du chemin. Vous ne pouviez le manquer, sans doute est-il tombé d'un véhicule. Ce genre d'objet sert habituellement pour stocker de l'énergie. Celui-ci est sans doute vide, mais il pourra vous servir quand même, d'autant plus que c'est un objet relativement rare.";
otherwise say "Ok[line break]".
Understand "carré/pavé" as cube.
klitt is a thing. The printed name of klitt is "du klitt". Understand "argent/monnaie/sous/pognon/fric" as klitt.
Instead of giving klitt to EmployeeCentreInfo, try showing klitt to EmployeeCentreInfo.
Instead of showing klitt to EmployeeCentreInfo, say "La femme vous confirme que cet argent n'a pas cours ici, aussi il vous faudrait le changer, vous pouvez d'ailleurs le faire dans ce bureau."
glutt is a thing. The printed name of glutt is "du glutt". Understand "argent/monnaie/sous/pognon/fric" as glutt.
Argent is a kind of value. 5 pièces specifies an argent.
klitt has an argent.
glutt has an argent.
Instead of examining the klitt :
say "Vous avez [argent of the klitt] de klitt. C'est la monnaie de chez vous."
Instead of examining the glutt :
say "Vous avez [argent of the glutt] de glutt. C'est la monnaie locale."
When play begins:
move klitt to player;
change the argent of the klitt to 9 pièces.
Instead of going south from sentier, say "Cette route vous ramènera vers chez vous, mais ce n'est pas la direction que vous souhaitez prendre pour le moment."
Before going nowhere from dehors:
if bibliotheque is not visited
begin;
say "Si vous quittez ce chemin maintenant, vous risquez d'être en retard pour votre rendez-vous.";
otherwise;
say "Vous avez peur de vous perdre si vous allez dans cette direction.";
end if.
EntreeVille is north of Sentier2. "Vous êtes face à une des murailles de Sarvegne. Des statues fantasmagoriques ornent tout le pourtour de ce mur, mais vous ne connaissez pas leur histoire". The printed name of EntreeVille is "Entrée de la ville".
After going in EntreeVille:
if EntreeVille is not visited
begin;
display the Figure of sarvegne2;
say "Vous arrivez devant la ville. Vous pouvez essayer d'entrer par la porte principale qui se trouve toute proche de là au nord-ouest ou contourner la ville par le nord-est pour trouver une entrée plus discrète."; continue the action;
Otherwise;
say "" ; continue the action;
end if;
an affiche is in EntreeVille. Affiche is a female thing. The description of affiche is "Un panneau annonçant les restrictions en vigueur pour entrer dans la ville.". The printed name of affiche is "affiche".
Understand "affiche/poster/panneau" as affiche.
Instead of going north from EntreeVille, say "Il y a un mur devant vous, prenez à gauche ou à droite.".
DevantPorteVille is northwest of EntreeVille. DevantPorteVille is north of EntreeVille.
DevantPorteVille is west of EntreeVille. The printed name of DevantPorteVille is "Devant la porte de la ville". "Vous imaginiez cette ville beaucoup plus animée, mais pour le moment la porte est close et vous ne voyez personne."
DerriereVille is northeast of EntreeVille. The printed name of DerriereVille is "Derrière la ville". DerriereVille is east of EntreeVille.
DerriereVille2 is northeast of DerriereVille. DerriereVille2 is east of DerriereVille. The printed name of DerriereVille2 is "Derrière la ville". "Vous êtes en dehors de la ville, derrière celle-ci.". Instead of examining DerriereVille2 for the second time, say "Vous êtes encore derrière la ville."
DerriereVille3 is northeast of DerriereVille2. The printed name of DerriereVille3 is "Derrière la ville". "Vous être maintenant diamétralement opposé à l'entrée principale.".
DerriereVille4 is northwest of DerriereVille3. The printed name of DerriereVille4 is "Derrière la ville". "Si vous continuez autour de la ville, vous pouvez rejoindre la porte principale au sud-ouest, ou revenir sur vos pas au sud-est. Ailleurs il n'y a rien d'intéressant.".
DevantPorteVille is southwest of DerriereVille4.
Before going southwest from DerriereVille4, say "Après une heure de marche vous revenez au point de départ."
Instead of going northeast from DevantPorteVille, say "C'est trop loin de continuer par cette voie.".
[After going in DerriereVille2:
if DerriereVille2 is not visited, say "Le chemin est long et monotone, vous ne trouvez rien de notable à cet endroit. Pendant que vous marchez, vous vous remémorer vos souvenirs. A la limite de votre champs de vision, la muraille en pierres de taille est très haute et lisse, ce qui en empêche toute escalade, et donc toute entrée par ce moyen.";
otherwise say "bli ."]
Before going to DerriereVille for the first time, say "Le chemin est long et monotone, vous ne trouvez rien de notable à cet endroit. Pendant que vous marchez, vous vous remémorer vos souvenirs. A la limite de votre champs de vision, la muraille en pierres de taille est très haute et reste lisse à hauteur d'homme, ce qui en empêche toute escalade, et donc toute entrée par ce moyen.".
Before going to DerriereVille2 for the first time, say "Vous longez la périphérie de la ville. Vous ne pouvez voir si l'activité de celle-ci est grande ou pas, car une protection entoure toute la ville, néanmoins vous pouvez le deviner avec la vision des vaisseaux qui vont dans toutes les directions. La plupart de ceux-ci étant destinés à la communication intra-muros, ils n'ont souvent pas de toiture."
Before going to DerriereVille3 for the first time, say "Vous continuez à contourner la ville. Les murailles en pierres sont toujours infranchissables de ce côté, mais à partir de cet endroit, moins entretenu que les abords de la grande entrée, de la mousse commence à recouvrir les murs."
Before going to DerriereVille4 for the first time, say "Vous commencez à fatiguer, vous avez déjà parcouru un long chemin."
mousse is a kind of supporter. a mousse is usually female. The description of mousse is "C'est une mousse verte un peu lumineuse, comme phosphorescente". The printed name of mousse is "de la mousse".
Understand "mousse/verte/herbe" as mousse.
After putting cube on mousse:
say "Le cube devient subitement brillant.";
change charge to 1.
Instead of taking mousse, say "Vous ne pouvez pas l'arracher ainsi."
mousse1 is a mousse. It is in DerriereVille3.
Mousse2 is a mousse. It is in ParcCentreVille.
The trappe is in DerriereVille2. The trappe is a female door. The trappe is north of DerriereVille2 and south of CaveauVille. CaveauVille is inside from DerriereVille2. The description of trappe is "C'est une trappe rouillée et sale. Pourtant vous voyez qu'il y a comme des restes de technologie qui s'inscrivent sur la surface de cette trappe, et notamment une sorte de plaque en métal." The trappe is lockable and locked and closed.
instead of pushing trappe, try opening trappe.
instead of pulling trappe, try opening trappe.
DansVille is up from CaveauVille.
Before going to CaveauVille:
if trappe is locked
begin;
say "Vous ne pouvez pas passer tant que cette trappe sera fermée.";
stop the action;
end if.
The plaque is in DerriereVille2. The plaque is a female scenery supporter. The description of plaque is "Cette plaque est toute rayée, mais elle ne semble pas avoir été touchée depuis des années. Elle est située près de la trappe." Understand "plaque en métal" or "plaque de métal" or "plaque en metal" or "plaque en metal" as plaque.
instead of taking plaque, say "C'est fixé sur une partie de la trappe.".
after examining trappe, change the plaque to not scenery.
after putting cube on plaque:
if charge of the cube is greater than 0
begin;
change the trappe to not locked;
change the charge of cube to 0;
say "Vous entendez un petit bruit.[line break]";
otherwise ;
say "ok[line break]";
end if.
The PorteEntreeVille door is south of DansVille and north of DevantPorteVille. It is a door and scenery. PorteEntreeVille is female, locked and closed. The printed name of PorteEntreeVille is "porte de la ville". The description of PorteEntreeVille is "Le portail principal de la ville est gigantesque, à l'image de la citée qu'elle protège. Depuis plusieurs siècles où il n'y a pas eu de siège, cette porte a eu plus un rôle d'apparât que de défense, mais néanmoins elle empêche tous les rôdeurs et voleurs d'y entrer facilement."
Understand "portail/porte/seuil/entree" as PorteEntreeVille.
Some gardes are a man. Understand "[gardes]" as the gardes. The description of the gardes is "Les gardes n'ont pas l'air concilliants. Ils portent de belles armures dorées, avec des motifs richement ouvragés sur leur poitrine. Le dessin central représente un aigle impérial, et vous ne pouvez voir le reste à cette distance." Understand "gardes/garde/molosse/armure/plastron/hallebarde/cotte/de/mailles/motifs/ouvragés/ poitrine/aigle/imperial" as "[gardes]".
Instead of pushing or pulling or attacking the PorteEntreeVille for the first time:
say "Vous approchez de la porte et tentez de la manipuler. A cet instant des gardes apparaissent entre deux créneaux.";
move 2 gardes to DevantPorteVille.
Every turn when in DevantPorteVille:
if PorteEntreeVille is locked and closed
begin;
if a random chance of 20 in 100 succeeds
begin;
say "La porte s'ouvre pour laisser passer un véhicule blindé, mais se referme aussitôt.";
[change PorteEntreeVille to unlocked;
change PorteEntreeVille to open;]
otherwise;
say "";
end if;
otherwise;
if a random chance of 33 in 100 succeeds
begin;
say "La porte se referme.";
change PorteEntreeVille to locked;
change PorteEntreeVille to closed;
otherwise;
say "";
end if;
end if.
Instead of pushing or pulling or attacking the PorteEntreeVille for the second time, say "Les gardes vous demandent de vous tenir tranquille."
Instead of pushing or pulling or attacking the PorteEntreeVille for the third time:
say "Les gardes vous attrapent et vous emprisonnent.";
move player to prison.
Instead of attacking the gardes:
say "Les gardes ne se laissent pas faire et vous emprisonnent.";
move player to prison.
[Instead of talking to the gardes:
say "Les gardes ne bougent même pas."]
[Instead of asking the gardes for the second time, say "Pas de réponse."]