Sarvegne
An interactive fiction by Eric Forgeot (2006) - the Inform 7 source text
Contents
Previous
Next
Complete text
RetrouveChien is a scene. RetrouveChien begins when the mecanicien is in location for the first time.
RetrouveChien ends when the location of RobotChien is Gare.
When RetrouveChien begins:
move RobotChien to MaisonAnita.
When RetrouveChien ends:
say "Le mécanicien vous remercie pour avoir retrouvé son chien.".
ChienFidele is a scene. ChienFidele begins when robotchien is fidele for the first time and the location is MaisonAnita. ChienFidele ends when the location of RobotChien is Gare.
Every turn when RobotChien is fidele:
say "Le chien vous suit fidèlement.";
move RobotChien to location.
When ChienFidele begins:
move RobotChien to location.
When ChienFidele ends:
now RobotChien is not fidele.
VoyagePlateau is a scene. VoyagePlateau begins when RetrouveChien ends. VoyagePlateau ends when the location is Plateau.
When VoyagePlateau begins:
say "Pour vous remercier de vos efforts, le mécanicien vous raconte que sa femme est friande de baies jaunes qui ne poussent que sur le plateau de Sarvegne. Ce plateau est normalement interdit de visite, mais depuis quelques années les contrôles sont moins stricts, aussi il va là-bas de temps en temps. L'homme vous explique que l'ancien centre de Sarvegne se trouvait là. Il peut vous y conduire si vous voulez. Voulez-vous y aller ?[line break]";
if player consents
begin;
say "Vous suivez le mécanicien et son chien dans un couloir sortant de la gare, et vous arrivez à un espace un peu désert où se trouve une petite navette datant de plusieurs dizaines d'années. Vous montez dedans, en espérant qu'elle tienne le voyage, et vous vous envolez au-delà de la ville. Le trajet est malgré tout confortable, et la vue du paysage agréable, sous un des soleils couchant. Après quelques dizaines de minutes de voyage, vous atterrissez sur un plateau.";
move mecanicien to Plateau;
move robotchien to Plateau;
now RobotChien is not fidele;
move the player to Plateau;
otherwise;
say "Comme vous voulez.";
remove mecanicien from play;
remove robotchien from play;
end if.
[Going to (the goal) is an action.
instead of going to a room when in Ville:
if location is in Ville
begin;
say "hello";
move player to the goal;
otherwise;
say "no";
end if.]
Ville is a region.
Ville2 is a region.
Before going nowhere from Ville for the first time, say "Cette ville est gigantesque, et vous ne pouvez malheureusement pas l'explorer en détail. Il vous faut aller à l'essentiel."
Before going nowhere from Ville for the second time, say "Cela vous mènerait trop loin d'aller dans cette direction."
DansVille, Prison, CaveauVille, ParcCentreVille, CentreVille, Rues1, CentreInfo, Gare, MaisonAnita are in Ville.
Bibliotheque and Rues2 are in Ville2.
Prison is a room.
CaveauVille is a room.
CentreInfo is a room. CentreInfo is northeast from DansVille. DansVille is outside from CentreInfo. The printed name of CentreInfo is "Centre d'information".
The description of CentreInfo is "Vous arrivez au centre d'information, qui est un lieu habituellement fréquenté par les nouveaux arrivants. [if CentreInfo is unvisited] Vous patientez un peu que l'on puisse vous recevoir, et après avoir indiqué le but de votre visite dans la ville, en omettant de dire que vous n'avez pas d'accès autorisé car vous n'êtes pas citoyen de la Fédération, on vous explique où se trouve l'adresse que vous leur demandez, dans une zone résidentielle un peu plus au nord d'ici. [end if] [if MaisonAnita is visited]Après une rapide vérification, vous comprenez que la bibliothèque est bien plus à l'est d'ici.[end if]"
EmployeeCentreInfo is a woman. She is in CentreInfo. The description of EmployeeCentreInfo is "Une femme jeune d'allure affable.". The printed name of EmployeeCentreInfo is "l'employée du centre d'information". Understand "employee/femme/guichetiere" as EmployeeCentreInfo.
A person has a table-name called conversation.
The conversation of EmployeeCentreInfo is the Table of EmployeeCentreInfo Conversation.
The conversation of Anita is the Table of Anita Conversation.
The conversation of Chauffeur is the Table of Chauffeur Conversation.
Instead of asking someone about something:
let the source be the conversation of the noun;
if topic understood is a topic listed in source
begin;
[if there is a cle entry and there is a turn_stamp entry
say "";
otherwise;
say "";
end if;]
if there is a turn_stamp entry
begin;
say "[The noun] vous a dit [summary entry][paragraph break]";
otherwise;
change turn_stamp entry to the turn count;
say "[reply entry][paragraph break]";
end if;
otherwise;
say "[The noun] vous regarde sans comprendre.";
end if.
[Instead of going south from bibliotheque:
[let the source be the conversation of anita;]
if there is a turn_stamp corresponding to a cle of 2 in the Table of Anita Conversation
[choose row with cle of "2" in the Table of Anita Conversation;
if there is a turn_stamp entry]
begin;
say "Vous devez maintenant trouver un moyen pour rejoindre ce plateau en dehors de la ville.";
continue the action;
otherwise;
continue the action;
end if.]
Understand "parler à [someone]" as chatting.
Understand "parler avec [someone]" as chatting.
[Understand "parler à [someone]" as a mistake ("Utilisez 'questionner' quelqu'un au sujet de quelque chose.").]
Understand "talk to [someone]" as a mistake ("Utilisez 'questionner' quelqu'un au sujet de quelque chose.").
Understand "talk [someone]" as chatting.
[Understand "parler avec [someone]" as chatting.]
[Understand the command "parler" as talk.]
Understand the command "bavarder" as parler avec.
[Understand the command "questionner" as parler avec.]
[Understand the command "parler avec/parler a" as talk.]
chatting is an action applying to one thing.
Carry out chatting:
say "Vous ne savez pas quoi dire."
Instead of chatting mecanicien for the first time:
if there is a turn_stamp corresponding to a cle of 2 in the Table of Anita Conversation
begin;
say "Vous dites au mécanicien qu'un chauffeur de taxi vous avait parlé de lui, et qu'il était possible de rejoindre le plateau à l'est de la ville. Il vous dit qu'il vous conduira volontiers là-bas, mais qu'il a perdu son chien récemment et qu'il ne veut pas faire de déplacement tant qu'il n'aura pas le coproce-coeur tranquille à ce sujet. Si vous savez comment l'aider il vous en sera d'ailleurs fort reconnaissant.";
otherwise;
say "Vous ne savez pas trop quoi lui dire.";
end if.
Instead of chatting mecanicien:
if the location is Plateau
begin;
if player carries a relique
begin;
say "L'homme regarde ce que vous avez en main, et ne semble pas très heureux de devoir vous ramenez en ville avec ces objets compromettants.";
stop the action;
end if;
say "Le mécanicien semble avoir fait une bonne récolte de baies. Voulez-vous repartir en ville avec lui ?";
if player consents
begin;
say "Vous remontez dans la navette pour quitter ce plateau tranquille et retrouver la cité animée de Sarvegne. L'homme vous dépose près de la gare et repart ensuite on ne sait où.";
move Player to Gare;
end if;
otherwise;
say "Vous ne savez pas trop quoi lui dire.";
end if.
[Instead of chatting chauffeur:
if there is a turn_stamp corresponding to a cle of 2 in the Table of Anita Conversation
begin;
say "Vous demandez au taxi s'il sait comment rejoindre le plateau à l'est de la ville. Il vous parle d'un de ses amis qui travaille à la gare et qui pourra vous obtenir un billet pour y aller.";
choose row 3 in the Table of Chauffeur Conversation;
change turn_stamp entry to 2;
otherwise;
say "Vous ne savez pas trop quoi lui dire.";
end if.]
Instead of chatting chauffeur:
if there is a turn_stamp corresponding to a cle of 2 in the Table of Anita Conversation
begin;
choose row 3 in the Table of Chauffeur Conversation;
change libelle entry to "le plateau";
end if;
say "Vous pouvez questionner [the noun] à propos de ces sujets : ";
let the source be the conversation of the noun;
repeat with N running from 1 to the number of rows in the conversation
begin;
say " [libelle in row N of the table of Chauffeur Conversation], ";
end repeat;
say " et vous ne voyez pas trop quoi d'autre pour le moment.[paragraph break]".
Table of Chauffeur Conversation
| libelle | topic | reply | summary | cle | turn_stamp |
| "la ville" | "Ville" | " Il ne vous raconte rien de spécial sur la ville. " | "des choses banales sur la ville." | 1 | a number |
| "argent" | "Argent/pieces/piece/monnaie" | "Le chauffeur explique qu'il est méfiant avec les pièces qu'on lui donne, en effet certaines n'ont pas cours à Sarvegne, et il ne peut pas tout accepter comme cela." | "qu'il ne voulait pas certain type de pièces." | 2 | |
| "--" | "plateau/grottes" | "Vous demandez au taxi s'il sait comment rejoindre le plateau à l'est de la ville. Il vous parle d'un de ses amis qui travaille à la gare et qui pourra vous obtenir un billet pour y aller." | "que vous deviez demander un ami à lui à la gare." | 3 |
Table of EmployeeCentreInfo Conversation
| libelle | topic | reply | summary | cle | turn_stamp |
| "la ville" | "Ville" | " 'Que voulez-vous savoir précisément sur la ville ?' " | "que vous pouviez la questionner sur des sujets précis" | 1 | a number |
| "votre argent" | "Argent/pieces/piece/monnaie" | "La femme regarde les pièces que vous lui montrez, et vous signale que cet argent n'a pas cours ici, aussi elle vous propose de faire changer ici votre monnaie si vous le désirez." | "qu'elle vous propose de changer votre argent." | ||
| "--" | "plateau/grottes" | "Vous demandez à la femme si elle sait comment rejoindre le plateau à l'est de la ville. Elle vous dit que la ville n'organise pas officielle de visite guidée de cette région plus ou moins interdite, et que vous devriez plutôt demander à des transporteurs indépendants si vous tenez vraiment à ce genre d'aventure." | "que vous devriez demander à quelqu'un d'autre tout ce qui concerne ce genre de sujet." | 3 |
Instead of chatting EmployeeCentreInfo :
if there is a turn_stamp corresponding to a cle of 2 in the Table of Anita Conversation
begin;
choose row 3 in the Table of EmployeeCentreInfo Conversation;
change libelle entry to "le plateau";
end if;
say "Vous pouvez questionner [the noun] à propos de ces sujets : ";
let the source be the conversation of the noun;
repeat with N running from 1 to the number of rows in the conversation
begin;
say " [libelle in row N of the table of EmployeeCentreInfo Conversation], ";
end repeat;
say " et vous ne voyez pas trop quoi d'autre pour le moment.[paragraph break]".
Table of Anita Conversation
| libelle | topic | reply | summary | cle | turn_stamp | |
| "la ville de Sarvegne" | "Ville/Sarvegne" | " Elle n'a pas grand chose de précis à vous raconter sur cette ville. Elle n'est pas née dans Sarvegne mais dans un village d'à côté. Puis ses parents sont allés habiter dans la ville lorsqu'elle était encore toute jeune. Elle a préféré rester là par la suite du fait des nombreuses opportunités que la ville offre. " | "que Sarvegne n'était pas sa ville natale." | 1 | a number | |
| "le site archéologique" | "site/archeologique/grottes/grotte" | "Elle a découvert une grotte à l'extérieur de la ville. Cette grotte contient d'anciens artefacts, et elle aimerait bien les rapporter chez elle pour les étudier plus facilement, mais alors elle se trouverait dans l'illégalité, et se ferait immédiatement repérer par les scientifiques qui viennent avec elle lors de ces sorties. Elle a déposé ces pièces dans une salle, parmi d'autres pièces de moindre valeur. Elle vous explique comment atteindre la grotte, qui se trouve sur un plateau. Elle sort alors sur le parvis de la bibliothèque pour vous montrer la direction de ce site, vers l'est, et vous revenez ensuite à l'intérieur." | "qu'il fallait trouver certains anciens objets dans un site archéologique en dehors de la ville." | 2 | -- | |
| "..." | "artefacts" | "Ces artefacts parlent d'une civilisation oubliée, et les ressortir au grand jour lui permettrait de mettre à mal le régime totalitaire des despotes qui contrôlent la ville et la région." | "que ces artefacts lui étaient nécessaire pour que les siens reprennent le pouvoir." | 3 | -- | |
| "..." | "peuple/tribus/paiens/peuple ancien" | "Effectivement, elle avait presque oublié l'existence de ces tribus païennes qui vivaient près de la ville. Peut-être que si vous essayez de les contacter ils pourront vous renseigner et vous conduire aux artefacts, mais cela sera sans doute plus long qu'en navette." | "que vous pouviez essayer de contacter cet ancien peuple." | 4 | -- |
Instead of chatting Anita :
if final is happening
begin;
say "Anita est très curieuse de voir ce que vous avez pu ramener.";
stop the action;
end if;
if there is a turn_stamp corresponding to a cle of 2 in the Table of Anita Conversation
begin;
choose row 3 in the Table of Anita Conversation;
change libelle entry to "les artefacts";
end if;
say "Vous pouvez questionner [the noun] à propos de ces sujets : ";
let the source be the conversation of the noun;
repeat with N running from 1 to the number of rows in the conversation
begin;
say " [libelle in row N of the table of Anita Conversation], ";
end repeat;
say " et vous ne voyez pas trop quoi d'autre pour le moment.[paragraph break]".
Understand "changer [something]" as changing.
Understand the command "causer" as ask.
changing is an action applying to one thing.
Carry out changing:
say "Pas pour cela."
Instead of changing klitt:
if the player has klitt and the player is in CentreInfo
begin;
say "Vous changez votre argent.";
change the argent of the glutt to the argent of the klitt / 2 pièces ;
move glutt to player;
change the argent of the klitt to 0 pièces;
remove klitt from play;
otherwise;
say "Vous pourriez faire cela si le contexte était meilleur, mais il manque quelque chose.";
end if.
Instead of changing glutt, say "On vous signale que cet argent à tout à fait cours ici, aussi il n'est pas nécessaire de le changer. De plus, si vous vouliez une monnaie extérieure, les frais de change seraient trop élevés par rapport à ce vous avez en poche."
MaisonAnita is a room. MaisonAnita is north from Rues1. The printed name of MaisonAnita is "Les quartiers nord". The description of MaisonAnita is "[if MaisonAnita is not visited]Vous marchez quelques kilomètres dans des quartiers calmes et ensoleillés. Le temps est frais et agréable, mais vous commencez à fatiguer un peu. Les bâtisses alentours sont assez basses en comparaison des immeubles de la ville. Vous arrivez bientôt devant l'adresse que l'on vous a indiqué. C'est une petite maison avec de grandes baies vitrées, et de nombreuses plantes à l'intérieur.[end if][if MaisonAnita is visited]Vous êtes dans des quartiers résidentiels aisés.[end if][if final is happening]Anita sort sur le seuil de sa maison lorsque vous approchez.[end if]".
a RobotChien is in MaisonAnita. Understand "robot/chien" as RobotChien. The printed name of RobotChien is "chien de garde". The description of RobotChien is "Un chien de garde cybernétique.". RobotChien is scenery. RobotChien can be fidele.
maisonobjet is in MaisonAnita. maisonobjet is female. maisonobjet is scenery.
Understand "porte/petite/maison/baies/vitrées/plantes/cloture" as maisonobjet. The printed name of maisonobjet is "la maison". The description of maisonobjet is "Une petite bâtisse propre et simple."
Instead of attacking maisonobjet, try going inside.
Before going to MaisonAnita:
if CentreInfo is unvisited, say "Cette zone pavillonaire est trop grande pour que vous y erriez sans renseignements précis." instead;
otherwise continue the activity.
DansMaisonAnita is a room. DansMaisonAnita is inside from MaisonAnita.
Instead of going inside from MaisonAnita for the first time:
change RobotChien to not scenery;
say "Un chien de garde surgit à ce moment-là et vous empêche d'approcher.[paragraph break]".
Instead of going inside from MaisonAnita[ for the second time]:
if RobotChien is not in location
begin;
say "[if final is not happening]Vous frappez à la porte, et une vieille femme vous ouvre. Elle vous explique que la personne que vous recherchez se trouve certainement à la grande bibliothèque de Sarvegne en ce moment, car elle travaille à temps presque complet là-bas.
Ce n'est pas tout près d'ici, mais à l'ouest de la ville, aussi vous aurez besoin de trouver un véhicule pour vous y rendre.[end if][if final is happening]Anita vous propose plutôt une balade en ville.[end if]";
Otherwise;
say "Le chien est toujours là.";
end if.
Instead of attacking RobotChien:
say "Il est vraiment plus fort que vous ne l'êtes, ses yeux étincellent d'une haine froide et désincarnée, et il ne fait qu'une bouchée de vous.";
end the game in death.
Instead of taking RobotChien, try touching RobotChien.
Instead of touching RobotChien:
say "Il grogne doucement mais sûrement en vous regardant, un peu d'huile noire bave de sa gueule d'acier, cela ne serait vraiment pas raisonnable de jouer avec lui.".
Instead of throwing cube at robotchien:
say "Vous lancer ce précieux objet comme si c'était un vulgaire projectile, il touche sa cible mais ne produit aucun dégat notable. En revanche le chien va sans doute en faire de visibles sur vous.";
end the game in death.
Instead of putting cube on robotchien:
say "Lorsque vous approchez un peu, le chien vous fait comprendre que vous n'êtes pas le bienvenu à faire quoi que ce soit contre lui.".
Instead of throwing tube at robotchien for the first time:
say "Vous lancez le tube vers le chien qui s'en empare satisfait, et vient le poser à vos pieds. Il ne vous dérangera sans doute plus maintenant. Il s'éloigne en passant sous la clôture derrière la maison.";
move the tube to location;
remove robotchien from play.
Instead of throwing tube at robotchien for the second time:
say "Vous lancez de nouveau le tube vers le chien qui s'en empare, et vient près de vous en remuant la queue. Il veut certainement continuer à jouer avec vous maintenant.";
now the RobotChien is fidele;
move the tube to location.
[Instead of going inside from MaisonAnita for the third time, say "Vous frappez à la porte, et la vieille femme vous ouvre de nouveau. Elle vous explique encore une fois ce qu'elle vous a déjà dit, à propos de la grande bibliothèque de Sarvegne, et de la direction de celle-ci à l'ouest de la ville."
Instead of going inside from MaisonAnita, say "Cela ne répond pas."]
Gare is a room. Gare is west from DansVille. The description of Gare is "[if location is not visited] Une gare gigantesque comme vous n'en avez jamais vue auparavant. Il n'y a plus de trafic aérien et les communications en navettes terrestres ont été réduite depuis quelques mois, mais cela n'empêche pas à la bâtisse de garder tout son prestige. [end if][if location is visited]La gare de Sarvegne vous impressionne toujours autant.[end if] "
Mecanicien is a man. The printed name of Mecanicien is "un mécanicien". The description of mecanicien is "[if location is Gare]Un mécanicien comme on en trouve beaucoup de nos jours, avec un habit rouge orangé et un écusson aux couleurs de la ville. Vous soupçonnez celui-ci d'être un robot, mais vous n'avez pas de preuve visible de cette impression.[End if][if location is Plateau]Le mécanicien est en train de cueillir des baies avec délicatesse et attention.[end if]".
After going in Gare:
if there is a turn_stamp corresponding to a cle of 3 in the Table of Chauffeur Conversation and Mecanicien is not in location
begin;
say "Vous rencontrez l'ami du chauffeur qui est un des mécaniciens de la station.";
move Mecanicien to location;
continue the action;
Otherwise;
say ""; continue the action;
end if;
Rues1 is a room. Rues1 is north from DansVille. The printed name of Rues1 is "Avenue principale - Quartiers Ouest."
The description of Rues1 is "Vous vous trouvez dans la rue principale de Sarvegne. [if Rues1 is not visited]Vous êtres pensif. Votre contact dans cette ville est une jeune fille qui travaille au conseil du Margrave. Vos divers échanges épistolaires ont permis de vous familiariser un peu avec elle, mais comment sera la réalité ? Elle vous a demandé de la rejoindre, mais n'a pu vous laisser qu'une adresse imprécise où vous pourriez la trouver.[end if][line break]".
CentreVille is a room. CentreVille is east from Rues1. The printed name of CentreVille is "Centre ville".
The description of CentreVille is "Le centre ville de Sarvegne est un endroit très bruyant. Différentes avenues mènent dans divers coins de la ville, et le bourdonnement incessants des navettes et voitures vous donne le tournis. Il y a également nombre de commerces et de passants, mais vous n'avez pas envie d'aller visiter ce genre d'attraction.".
Instead of going east from CentreVille, say "Cette avenue est trop longue et surtout trop passagère pour que vous puissiez la suivre à pied, en plus vous risqueriez de vous faire renverser.".
ParcCentreVille is a room. ParcCentreVille is southeast from CentreVille.
The description of ParcCentreVille is "[if location is not visited]Vous arrivez au parc. [end if]Ce parc sert un peu de poumon pour la ville, il est très vaste, et filtre la plupart de la pollution occasionnée par les hommes, bien que le reste de la ville soit très vert. La faune et la flore qui sont là vous émerveillent le temps de votre visite."
The description of CaveauVille is "A cet endroit qui sert visiblement pour l'assainissement de la ville, une petite ouverture cachée est dissimulée aux regards de tous. Une sortie remonte ensuite vers l'intérieur de la ville.". Understand "ouverture/trappe" as CaveauVille.The printed name of CaveauVille is "Un caveau dans la ville".
a tube is in CaveauVille. The description of tube is "Un tube un peu rouillé, un peu moins long qu'une coudée."
The description of DansVille is "Vous êtes dans les rues de Sarvegne. [if DansVille is unvisited]Cette ville est emplie d'un mélange de technologie et de traditions, des dômes multicolores brillent au loin sous l'influences des deux soleils orange et vert, et certaines partie de murs en cristal reflètent les couleurs du désert qui s'étend au delà de l'enceinte de la cité.[end if] Le centre d'information de la ville est au nord-est, et vous pouvez voir les bâtiments imposants de la gare à l'ouest. Il reste également d'autres coins à explorer.".
The printed name of DansVille is "Dans la ville.".
[taxi dans rues1 et centreville -> rues2 autre bout de la ville]
In CentreVille is a vehicle called a taxi. The description of taxi is "Un véhicule rapide [if a random chance of 1 in 2 succeeds]sur coussin d'air [end if]qui n'a pas grand chose à voir avec ceux de la petite ville d'où vous provenez."
Understand "coussin d'air/coussin/coussins/voiture/vehicule" as Taxi.
Rues2 is a room. The printed name of Rues2 is "Avenue principale - Quartiers Est". The description of Rues2 is "Bien que Sarvegne soit une cité prospère, cette partie de la ville semble plus riche que l'autre. La bibliothèque n'est pas loin, un peu plus au nord."
TaxiBiblio is a scene. TaxiBiblio begins when the player is in taxi and the location is in Ville.
TaxiBiblio ends when the player is in Rues2 or in CentreVille.
TaxiBiblio2 is a scene. TaxiBiblio2 begins when the player is in taxi and the location is in Ville2.
TaxiBiblio2 ends when the player is in Rues2 or in CentreVille.
When TaxiBiblio ends:
say "Vous ressortez du taxi et vous vous retrouvez au bord du trottoir."
When TaxiBiblio begins:
say "Le chauffeur vous regarde et vous demande où vous voulez aller.";
if MaisonAnita is unvisited
begin;
say "Vous n'avez pas de destination précise en tête, aussi vous décidez de ressortir rapidement du taxi.";
move player to location;
otherwise;
say "Vous demandez à aller près de la bibliothèque. Le véhicule se soulève alors à quatre pieds de haut, et part vers la destination choisie.";
if player has glutt begin;
move the taxi to Rues2;
move player to Rues2;
change the argent of the glutt to the argent of the glutt - 1 pièces ;
say "Vous donnez une pièce au conducteur en paiement du transport." ;
otherwise;
say "Le chauffeur vous regarde d'un air soupçonneux, et vous demande si vous avez de quoi payer la course. Vous lui tendez quelques pièces, mais elles lui sont inconnues et il n'en veut pas.";
move player to location;
end if;
end if.
When TaxiBiblio2 begins:
if player has glutt
begin;
say "Le chauffeur vous regarde et vous demande où vous voulez aller.";
if there is a turn_stamp corresponding to a cle of 2 in the Table of Anita Conversation
begin;
if there is a turn_stamp corresponding to a cle of 5 in the Table of Chauffeur Conversation
begin;
say "Vous lui demandez de vous conduire à la gare.";
move the taxi to DansVille;
say "Vous donnez une pièce au conducteur en paiement du transport." ;
change the argent of the glutt to the argent of the glutt - 1 pièces ;
move player to Gare;
otherwise;
say "Vous demandez à retourner dans le centre de la ville.";
move the taxi to CentreVille;
change the argent of the glutt to the argent of the glutt - 1 pièces ;
say "Vous donnez une pièce au conducteur en paiement du transport." ;
move player to CentreVille;
end if;
otherwise;
say "Voulez-vous retourner au centre-ville ?";
if player consents
begin;
move the taxi to CentreVille;
move player to CentreVille;
change the argent of the glutt to the argent of the glutt - 1 pièces ;
say "Vous donnez une pièce au conducteur en paiement du transport." ;
otherwise;
move player to location;
end if;
end if;
otherwise;
say "Le chauffeur vous regarde d'un air soupçonneux, et vous demande si vous avez de quoi payer la course. Comme vous n'en avez plus, il refuse de vous conduire.";
move player to location;
end if.
When TaxiBiblio2 ends:
say "Vous ressortez du taxi et vous vous retrouvez au bord du trottoir."
[Understand the command "sortir" as something new.
Understand "sortir du taxi" as a mistake ("Pour sortir d'un véhicule, il suffit juste de 'sortir'") when the player is in a vehicle.]
Chauffeur is a man. Chauffeur is in taxi. The printed name of Chauffeur is "le chauffeur".
Sortir is an action applying to nothing.
Understand the command "sortir" as something new.
Understand "quitter le taxi" as exiting.
Instead of going somewhere when the player is in a vehicle, say "Ce n'est pas vous qui conduisez ce véhicule.".
[Instead of leaving [vehicle], try exiting.]
[Some Taxis are a vehicle. Understand "[taxis]" as the taxis. The description of the taxis is "Un véhicule rapide qui n'a pas grand chose à voir avec ceux de la petite ville d'où vous provenez."
Understand "taxi/navettes" as "[taxis]".
When the player enters DansVille, move 2 taxis to CentreVille.]
Bibliotheque is a room. Bibliotheque is north from Rues2. Bibliotheque is inside from Rues2.
The printed name of bibliotheque is "Bibliothèque".
The description of bibliotheque is "La bibliothèque de Sarvegne est un beau et vaste bâtiment de marbre clair[if location is unvisited], sur lequel est inscrit au fronton 'Vuy Arkjöda Vreffel - Vuy Arkjäta Vrill', la devise de Sarvegne, et qui signifie 'Soit attiré par la connaissance, soit volontaire de ton destin'[end if].".
Anita is a woman. Understand "jeune fille/fille" as Anita. The description of Anita is "Anita est une très belle jeune fille aux cheveux noirs. Elle n'est pas très grande, mais semble avoir beaucoup de détermination. Ses habits sont raffinés, en accord avec sa caste."
Instead of taking Anita, say "Elle n'est pas transportable et vous la vexeriez certainement !"
Anita is in Bibliotheque. Instead of telling Anita about something, try asking Anita about it.
Instead of going outside from bibliotheque or going south from bibliotheque:
if the player has mallette
begin;
continue the action;
otherwise;
if there is a turn_stamp corresponding to a cle of 2 in the Table of Anita Conversation
begin;
say "'N'oubliez pas cette mallette, elle vous servira à rapporter discrètement les reliques. Il n'y a de la place que pour quatre d'entre elles, aussi vous ne prendrez que les plus importantes pour moi. Vous les identifierez grâce à un programme dans mon ordinateur.' Elle vous remet une petite valise sombre.";
move the mallette to player;
say "Vous devez maintenant trouver un moyen pour rejoindre ce plateau en dehors de la ville.";
continue the action;
otherwise;
say "Vous devez maintenant trouver un moyen pour rejoindre ce plateau en dehors de la ville.";
continue the action;
end if;
end if.
Before going to bibliotheque for the first time:
say "Vous parcourez sous les allées ombragée les quelques mètres qui vous restent pour atteindre l'entrée de la bibliothèque. Les trottoirs ici ont des circuits imprimés à l'air libre, sans doute que la municipalité est en train d'installer de nouveaux capteurs pour un usage dont vous ignorez tout.";
display the figure of sarvegne;
say "Lorsque vous entrez elle sait que c'est vous qu'elle attend, et elle quitte sa place pour venir vous saluer. Elle vous explique qu'elle est présente ici tous les jours, mais elle partage ce temps avec un site archéologique qui vient d'être découvert récemment.".
The mallette is in bibliotheque. The mallette is a female container. The mallette is scenery. The carrying capacity of the mallette is 4. Understand "mallette" or "valise" as mallette. The description of mallette is "une petite mallette noire.".
instead of inserting mallette into sacdos, say "Votre sac à dos ne peut contenir cette valise.".
Instead of showing mallette to Anita, try giving mallette to Anita.
instead of giving mallette to Anita:
if final is happening
begin;
if artefact2 is in mallette and artefact4 is in mallette and artefact5 is in mallette and artefact7 is in mallette
begin;
say "Elle semble très heureuse de votre collecte. Félicitation.[line break]Vous retournez ensemble à la bibliothèque où elle va rechercher quelques documents qui pourront lui servir pour la confrontation finale avec les membres corrompus du gouvernement. En effet, la preuve historique de ce foyer de peuplement sur le sol de la région de Sarvegne permettra de confondre le groupe d'usurpateurs qui a pris le pouvoir autoritairement il y a quelques dizaines d'année. Elle doit avant cela terminer d'analyser les précieuses pièces que vous lui avez ramenées. Mais ceci est une autre histoire...";
display the Figure of titre;
say "Anita ouvre le petit coffret en lapis-lazuli. Elle en sort une plaque de cuivre gravé qu'elle lit puis qu'elle vous tend. Il y figure ces lignes :[line break][line break][italic type]
Je garde avec moi ce bouclier d'étoiles[line break]
Qui nous protège d'une bannière étoilée[line break]
Située alors si loin qu'elle nous paraissait inoffensive[line break]
Mais nous avons traversé des lieues dans l'espace[line break]
Puis conquit des terres hospitalières et libres[line break]
Nos chariots roulant inlassablement sur l'herbe et le sable[line break]
Nos arcs et nos flèches toujours à notre portée[line break]
Des ennemis veulent nous passer au fil de leur épée[line break]
et nous imposer une religion nouvelle[line break]
Mais quoi qu'il en soit nous resterons toujours nous-même.[line break][roman type]";
end the game in victory;
otherwise;
say "Certains des artefacts dans la valise n'ont pas supporté le voyage et se sont abimés, mais ce n'est pas si grave dans un sens puisque ce n'est pas exactement ce qu'elle attendait de vous. Quelle déception, elle ne pourra pas continuer son travail de réhabilitation et de recherche. Sans doute fera-t-elle appel par la suite à quelqu'un de plus doué pour réussir cette mission.";
end the game saying "[line break]** Vous avez perdu **.[line break]";
end if;
otherwise;
say "Vous en aurez encore besoin.";
end if.
The calculateur is in bibliotheque. The calculateur is a device. The charge of the calculateur is 6.
after switching on calculateur:
if location is Grottes2
begin;
if charge of the calculateur is greater than 7
begin;
say "Vous allumez l'ordinateur, et utilisez le programme d'analyse qu'on vous a montré, pour comparer les piles d'objets présents et dégager ceux qui correspondent à la collection d'Anita.";
change artefact1 to not scenery;
change artefact2 to not scenery;
change artefact3 to not scenery;
change artefact4 to not scenery;
change artefact5 to not scenery;
change artefact6 to not scenery;
change artefact7 to not scenery;
move Anita to MaisonAnita;
remove tube from play;
say "Malheureusement, entre-temps certains de ses collègues ont apportés d'autres pièces de moindre importance, et il va vous falloir les séparer du reste pour savoir quoi ramener.";
otherwise;
say "Vous allumez l'ordinateur, et voulez utiliser le programme d'analyse, mais la batterie semble trop faible pour cela.";
end if;
otherwise;
continue the action;
end if.
instead of examining calculateur:
if player is in bibliotheque and player is not carrying calculateur then say "Cet ordinateur portable appartient visiblement à Anita.";
if charge of the calculateur is less than 1 then say "Il semble déchargé.";
if the calculateur is switched on, say "L'ordinateur semble opérationnel. Il fonctionne sous un environnement de type Unix auquel vous n'êtes pas trop habitué, mais affiche un programme d'analyse de données archéologiques qui semble convivial et facile à utiliser.";
if location is grottes2
begin;
if artefact2 is not scenery, say "Vous consultez le manuel du programme, et il affiche également une nomenclature détaillée des types de reliques que l'on peut trouver. Vous trouvez aussi une note, sans doute d'Anita, qui indique ce petit poème : [line break][line break] [italic type]
Je regarde vers les étoiles, [line break]
représentation fidèle de nos dieux, [line break]
Je regarde vers les forêts, les mers et leurs habitants,[line break]
symboles de force et de liberté,[line break]
Le soleil et les saisons, cycles récurrents,[line break]
Rythment nos vies et nos rites.[line break]
L'arc tendu, comme le fil de l'existence,[line break]
Est hors de porté de ce qui pourrait le remplacer.[line break] [roman type]";
otherwise;
say "C'est un ordinateur portable.";
end if.
After taking calculateur:
if Anita is in location then say "Anita vous dit que vous pouvez emprunter son ordinateur portable si vous pensez en avoir besoin. Il pourra vous aider à identifier les artefacts, mais elle vous prévient que sa batterie se décharge vite. [line break]";
otherwise say "Ok[line break]".
Understand "ordinateur/laptop/portable" as calculateur.
Every turn when the player has calculateur and the calculateur is switched on:
decrease the charge of the calculateur by 1;
move unix to location;
if the charge of the calculateur is 2 then say "L'ordinateur va sans doute s'éteindre bientôt.";
if the charge of the calculateur is less than 1
begin;
say "L'ordinateur n'a plus d'énergie et s'éteint ![line break]";
silently try switching off the calculateur;
end if.
instead of putting cube on calculateur:
if calculateur is switched on, say "Vous devriez éteindre l'ordinateur pour le recharger, sinon cela pourrait l'endommager.";
if charge of the cube is greater than 0
begin;
change the charge of calculateur to 30;
change the charge of cube to 0;
say "Vous touchez l'ordinateur avec le cube. Un petit bourdonnement et de faibles vibrations se font ressentir, et le cube communique de son énergie à l'ordinateur.";
otherwise ;
say "Le cube est déjà vide et il ne peut rien faire de plus pour le moment, aussi vous le reprenez avec vous.";
end if.
The livres are scenery in bibliotheque. The description of livres is "Cette bibliotheque est emplie de livres, de papier ou électronique.". Understand "livre/livres/bibliotheque/endroit" as livres.
The borne is scenery in bibliotheque. The borne is female. The description of borne is "Une simple borne de consultation des fonds documentaires de cette bibliothèque.". Understand "borne" and "borne interactive" as borne.
Instead of searching livres:
say "Vous consultez rapidement sur une borne interactive la notice générale des documents qui pourraient vous intéresser ici. Vous prenez un des livres en question et vous y apprenez qu'un peuple respectant encore les anciens rites interdits habite à l'est de Sarvegne.";
change the east exit of DerriereVille3 to CampAncien;
change the west exit of CampAncien to DerriereVille3;
choose row 4 in the Table of Anita Conversation;
change libelle entry to "le peuple ancien".