Sarvegne
An interactive fiction by Eric Forgeot (2006) - the Inform 7 source text
Contents
Previous
Complete text
Final is a scene. Final begins when Anita is in maisonanita for the first time.
ReseauGrottes is a region. Grottes and Grottes2 are in ReseauGrottes.
Before going nowhere from ReseauGrottes:
if bibliotheque is not visited
begin;
say "";
otherwise;
say "Vous risquez de vous perdre si vous allez en dehors des lieux répertoriés et balisés par Anita.";
end if.
CampAncien is a room. The printed name of CampAncien is "Un camp".
The description of CampAncien is "[if location is not visited]Après plusieures lieues de marche, vous arrivez à proximité d'un campement.[end if]Vous êtes dans un camp, caché dans le désert, mais en bordure d'une forêt. Il n'y a plus personne ici, mais vous voyez des chariots et des arcs abandonnés.".
accessoiresCamp is scenery in campancien. Understand "chariot/chariots/camp/arc/arcs" as accessoiresCamp. The description of accessoirescamps is "Divers objets appartenant à la tribu qui habitait là.".
Instead of taking accessoirescamp, say "Ce genre d'objet un peu archaïque ne vous sera d'aucune utilité dans le moment présent.".
Plateau is a room. The printed name of Plateau is "Le plateau de l'ancien site de Sarvegne".
The description of Plateau is "Vous êtes sur le plateau qui correspondait à l'ancienne ville de Sarvegne, aux temps antiques. [if Plateau is not visited]Ce plateau fait environ la taille d'un stade, et présente quelques traces de végétation. Il y a également quelques gros rochers de taille imposante, mais vous ne venez pas ici pour faire de la géologie.[end if] Des trous descendent vers le réseau de grotte sous le plateau.".
PlateauFake is scenery in Plateau.
Understand "grottes/grotte/plateau/trou/foyer/sarvegne/ruines/plantes/arbustes/trous/vegetation/rochers/roche" as plateauFake. The printed name of PlateauFake is "plateau". The description of plateaufake is "Ce plateau ainsi que le réseau de grottes qui passe en dessous représentaient le premier foyer de peuplement de la cité de Sarvegne. Mais la cité a depuis complètement disparu, le plateau est entièrement vide à l'exception de quelques arbustes, plantes et baies qui restent là.".
Navette is in Plateau. Navette is a female vehicle. The printed name of navette is "la navette".
Instead of entering navette, try chatting mecanicien.
baie is a kind of thing. BaieJaune is a baie. The printed name of BaieJaune is "des baies jaunes". BaieJaune is in plateau. The description of BaieJaune is "Ces baies jaunes sont presque lumineuses.". Understand "baies/baie/jaune/jaunes" or "baies jaunes" as baiejaune.
Instead of taking baiejaune, say "Vous n'avez pas le temps de déguster les spécialités locales."
Grottes is down from Plateau.
The description of Grottes is "[if Grottes is not visited]L'entrée principale descend en pente douce. Anita vous a expliqué où elle avait caché les artefacts, et vous reconnaissez facilement les lieux qu'elle vous a décrits. [end if]Vous êtes dans une salle qui fut autrefois un grand hall d'accueil princier. Le réseau de grottes s'étend bien au-delà de ce que vous voyez, et des ouvertures partent un peu partout. Mais Anita vous a dit de ne pas quitter le chemin qui s'étend sur votre gauche tout à l'entrée, et vous atteindrez directement les artefacts. La sortie se trouve en remontant la rampe[if Grottes is not visited] que vous venez d'emprunter[end if]."
Grottes2 is west from Grottes.
The description of grottes2 is "[if location is not visited]Cette partie se prolonge encore jusqu'à aboutir à [end if]une salle de taille moyenne[if location is not visited], mais emplie d'objets hétéroclites. Visiblement les scientifiques ont décidé de stocker là certaines de leurs diverses découvertes en attendant que la situation vis à vis du gouvernement de Sarvegne se débloque[end if].".
The printed name of grottes2 is "La salle de stockage des reliques.".
a relique is a kind of thing.
Instead of attacking a relique, say "Ce sont des objets anciens, vous devez normalement les respecter."
Instead of touching a relique, say "Vous retournez l'objet dans tous les sens, mais pour vous qui n'êtes pas un spécialiste, il ne vous livrera pas facilement son secret.".
Instead of inserting a relique into sacdos, say "Vous ne pouvez mettre ce genre d'objet ancien dans un sac à dos sans aucune protection, vous devriez utiliser une valise capitonnée à la place.".
artefake is scenery relique in grottes2. The description of artefake is "Divers artefacts.". The printed name of artefake is "des artefacts anciens". Understand "artefact" or "tout" as artefake.
the artefact1 is female scenery relique in grottes2. The description of artefact1 is "Une carte hexagonale, en cuir rouge, avec seulement six points cardinaux, d'un territoire inconnu.". The printed name of artefact1 is "carte ancienne". Understand "carte/cuir" or "carte ancienne" as artefact1.
the artefact2 is scenery relique in grottes2. The description of artefact2 is "Ceci n'est qu'une petite partie d'un bouclier ancien, où on trouve des incrustations dans un autre métal, sans doute de l'argent, qui forment des points semblant disposés aléatoirement.".The printed name of artefact2 is "fragment de bouclier ancien". Understand "bouclier/points/argent" or "bouclier ancien" as artefact2.
the artefact3 is scenery relique in grottes2. The description of artefact3 is "Ce couteau a sur son manche et sa lame une série de pentagrammes et de croissants occultes gravés. La lame est torsadée, il semble utilisé pour accomplir des rituels anciens.".The printed name of artefact3 is "couteau". Understand "couteau" or "lame/pentagrammes" as artefact3.
the artefact4 is female scenery relique in grottes2. The description of artefact4 is "Une boîte en lapis-lazuli et avec des décorations ainsi que le fermoir en bronze, on y voit des motifs géométriques en forme de roues qui donnent l'impression de tournoyer de façon hypnotique.".The printed name of artefact4 is "petite boîte". Understand "boite/lazuli" or "petite boite" as artefact4.
Instead of opening artefact4, say "Elle est fermée par un dispositif dont vous ignorez tout.".
the artefact5 is scenery relique in grottes2. The description of artefact5 is "Un vase en terre cuite, sur lequel est peint un sanglier doré.".The printed name of artefact5 is "vase". Understand "vase en terre cuite" or "terre/vase/sanglier" as artefact5.
the artefact6 is female scenery relique in grottes2. The description of artefact6 is "Une croix miniature, dans le genre de celle que l'on utilisait dans les anciens temps pour crucifier les criminels.".The printed name of artefact6 is "croix". Understand "croix" or "crucifix" as artefact6.
the artefact7 is female scenery relique in grottes2. The description of artefact7 is "Une pointe de flèche en bronze.".The printed name of artefact7 is "pointe de flèche". Understand "pointe" or "fleche" or "pointe de fleche" as artefact7.
[Include Basic Screen Effects by Emily Short. Include Menus by Emily Short.
Table of Amusing Matter
| title | subtable | description | toggle |
| "Epilogue" | a table-name | "Anita ouvre le petit coffret en lapis-lazuli. Elle en sort une plaque de cuivre gravé qu'elle lit puis qu'elle vous tend. Il y figure ces lignes :[line break][line break][italic type] | |
| Je garde avec moi ce bouclier d'étoiles[line break] | |||
| Qui nous protège d'une bannière étoilée[line break] | |||
| Située alors si loin qu'elle nous paraissait inoffensive[line break] | |||
| Mais nous avons traversé des lieues dans l'espace[line break] | |||
| Puis conquit des terres hospitalières et libres[line break] | |||
| Nos chariots roulant inlassablement sur l'herbe et le sable[line break] | |||
| Nos arcs et nos flèches toujours à notre portée[line break] | |||
| Des ennemis veulent nous passer au fil de leur épée[line break] | |||
| et nous imposer une religion nouvelle[line break] | |||
| Mais quoi qu'il en soit nous resterons toujours nous-même.[line break][roman type]" | a rule | ||
| "Military Revisions" | a table-name | "Did you try... [paragraph break] allying a Greek city-state with the Persians? (try >MEDIZE) [line break] playing Athens as a land-based power?" | a rule |
Rule for amusing a victorious player:
change the current menu to the Table of Amusing Matter;
change the current menu title to "Epilogue";
carry out the displaying activity;
clear the screen.]
Rule for amusing a victorious player: say "Anita ouvre le petit coffret en lapis-lazuli. Elle en sort une plaque de cuivre gravé qu'elle lit puis qu'elle vous tend. Il y figure ces lignes :[line break][line break][italic type]
Je garde avec moi ce bouclier d'étoiles[line break]
Qui nous protège d'une bannière étoilée[line break]
Située alors si loin qu'elle nous paraissait inoffensive[line break]
Mais nous avons traversé des lieues dans l'espace[line break]
Puis conquit des terres hospitalières et libres[line break]
Nos chariots roulant inlassablement sur l'herbe et le sable[line break]
Nos arcs et nos flèches toujours à notre portée[line break]
Des ennemis veulent nous passer au fil de leur épée[line break]
et nous imposer une religion nouvelle[line break]
Mais quoi qu'il en soit nous resterons toujours nous-même.[line break][roman type]".
Index map with EPS file,
room-name-length set to 15,
route-thickness set to 2,
room-outline set to off,
map-outline set to off,
route-colour set to "Chocolate",
room-colour set to "Burly Wood",
title set to "Sarvegne",
font set to "Baskerville".
[nouveaux verbes]
Include (-
Extend 'frapper' first
* 'a'/'à' noun -> GoIn;
-).
Include (-
Extend 'questionner' first
* creature -> ask;
-).
Mendier is an action applying to nothing.
Understand "mendier" as mendier.
[Understand "take [everything]" as a mistake ("Vous ne pouvez pas posséder tout le monde qui vous entoure juste sur une lubie...").]
Understand "aide" or "help" or "hints" or "astuces" as a mistake ("Ce jeu est une aventure textuelle, vous devez entrer des commandes pour décrire ce que vous voulez faire. Veuillez vous référer aux fichiers d'aide joints, ou taper 'solution' pour la liste complète des commandes à entrer si vous êtes vraiment bloqué, ou 'plan' pour visualiser un plan rapide. Si vous avez des problèmes pour parler 'avec' quelqu'un, utilisez la commande 'questionner' untel 'au sujet de...', et veuillez abréger certaines formes non comprises. Au sujet des directions, pour des raisons de clarté il est possible d'écrire 'n' pour 'nord', mais 'nord-ouest' s'écrira ainsi et non pas 'no'[line break]
Dans ce jeu votre but est d'arriver à récupérer des objets dans un lieu à l'écart de la ville. Vous devez tout d'abord rencontrer Anita, votre contact. Pour arriver à elle, vous devrez avant cela entrer dans la ville par un passage détourné, ouvrir la trappe qui en bloque l'entrée avec un objet énergisé par un végétal, aller au centre d'information du centre ville pour trouver son habitation, ensuite détourner avec un tube qui fera office de jouet un molosse qui garde la maison, apprendre que la jeune fille se trouve à la bibliothèque pour y étudier, changer son argent pour la monnaie locale pour pouvoir prendre un taxi, et arriver à destination. Ensuite il faudra emprunter une malette et un ordinateur, apprendre du chauffeur de taxi comment aller dans un endroit interdit, rencontrer son ami mécanicien à la gare, retrouver le molosse décidément assez joueur de celui-ci, et arriver sur le plateau en dehors de la ville. L'ordinateur permettra d'identifier des artefacts perdus, en étudiant quelques notes qui devraient permettre par élimination de mettre de côté ce qui n'est pas l'objet d'étude d'Anita, et de rapporter les bons artefacts à votre contact. Si ces indications ne sont pas suffisantes, vous pouvez obtenir le cheminement complet avec la commande 'solution'
").
Plan is an action applying to nothing.
Understand "plan" or "carte" as plan.
check plan:
display the figure of plansarvegne.
Carry out plan:
display the figure of plansarvegne.
Understand "credits" or "info" as a mistake ("Jeu créé pour la compétition ifiction.free.fr. Ceci est la version améliorée.[line break]
(c) droits réservés - 2006[line break]").
Understand "cheminement" or "solution" or "walkthrough" as a mistake ("
Aller au nord / fouiller le buisson / prendre le cube / nord / nord-est / penser / est / regarder trappe / nord-est / regarder la mousse / poser le cube sur la mousse / regarder le cube / nord-ouest
revenir / prendre le cube / sud-ouest / regarder la plaque / poser le cube sur la plaque / ouvrir la trappe / prendre le cube / nord-est / poser le cube sur la mousse / prendre le cube / revenir / entrer/ prendre le tube / monter / nord-est /sortir
nord / nord / frapper à la porte / lancer tube sur le chien / frapper à la porte / sud / sud / nord-est / parler avec la femme / questionner la femme au sujet de argent / changer argent / sortir
nord / est / entrer dans le taxi / aller au nord / regarder Anita / parler avec Anita
questionner Anita au sujet du site / questionner Anita au sujet des artefacts / chercher les livres / questionner anita au sujet du peuple ancien / prendre ordinateur / sortir / questionner chauffeur au sujet du plateau / entrer dans le taxi
ouest / sud / ouest / parler avec mécanicien / est / nord / nord / prendre tube / lancer tube sur le chien / sud / sud / ouest / oui
descendre / ouest / allumer ordinateur / éteindre ordinateur / poser le cube sur l'ordinateur / allumer ordinateur / regarder
examiner la carte / examiner le bouclier / examiner couteau / examiner boite / examiner vase / examiner la croix / examiner la pointe / regarder l'ordinateur
prendre bouclier / mettre le bouclier dans la valise / prendre boite / mettre la boite dans la valise / prendre vase / mettre le vase dans la valise / prendre pointe / mettre la pointe dans la valise
éteindre ordinateur / est / remonter / entrer dans la navette / oui / est / nord / nord / parler avec Anita / donner valise a Anita
").
Check mendier:
if location is in ville, say "Vous ne pouvez vous résoudre à faire cela ici." instead.
Carry out mendier:
say "Vous ne voyez pas l'intérêt de faire cela ici."
Test un with "Aller au nord / fouiller le buisson / prendre le cube / nord / nord-est / penser / est / regarder trappe / nord-est / regarder la mousse / poser le cube sur la mousse / regarder le cube / nord-ouest"
Test deux with "revenir / prendre le cube / sud-ouest / regarder la plaque / poser le cube sur la plaque / ouvrir la trappe / prendre le cube / nord-est / poser le cube sur la mousse / prendre le cube / revenir / entrer/ prendre le tube / monter / nord-est /sortir"
Test trois with "nord / nord / frapper à la porte / lancer tube sur le chien / frapper à la porte / sud / sud / nord-est / parler avec la femme / questionner la femme au sujet de argent / changer argent / sortir"
Test quatre with "nord / est / entrer dans le taxi / aller au nord / regarder Anita / parler avec Anita"
Test cinq with "questionner Anita au sujet du site / questionner Anita au sujet des artefacts / chercher les livres / questionner anita au sujet du peuple ancien / prendre ordinateur / sortir / questionner chauffeur au sujet du plateau / entrer dans le taxi /"
Test sept with "ouest / sud / ouest / parler avec mécanicien / est / nord / nord / prendre tube / lancer tube sur le chien / sud / sud / ouest / oui"
Test huit with "descendre / ouest / allumer ordinateur / éteindre ordinateur / poser le cube sur l'ordinateur / allumer ordinateur / regarder"
Test neuf with "examiner la carte / examiner le bouclier / examiner couteau / examiner boite / examiner vase / examiner la croix / examiner la pointe / regarder l'ordinateur"
Test dix with " prendre bouclier / mettre le bouclier dans la valise / prendre boite / mettre la boite dans la valise / prendre vase / mettre le vase dans la valise / prendre pointe / mettre la pointe dans la valise"
Test onze with "éteindre ordinateur / est / remonter / entrer dans la navette / oui / est / nord / nord / parler avec Anita "
Test tout with "test un / test deux / test trois / test quatre / test cinq / test sept / test huit / test neuf / test dix / test onze"
Test tout2 with "test un / test deux / test trois / test quatre / test cinq / test six"
Test six with " ouest / sud / bas / sud / nord-est / est "
Test sixbis with "test un / test deux / test trois / test quatre "
[bug : parler au chauffeur <> parler avec chauffeur
lancer tube °vers° le chien
a device can't be a supporter ! (can't you put a cup of tea on a computer tower ?)
auto line break...
apostrophes pb avec guillemets
split screen
can't use composed word in dialogue
supporter and backdrop are incompatible.
female scenery supporter = pb affichage : on laplaque est ...
disable "take all"
add Constant AMUSING_PROVIDED;
]